; $VER: DeepXInstall 1.2 (29.04.96)

(if (= @language "english")
(	(set #drawer "Select a drawer where to copy DeepX")
	(set #copy "Copying DeepX")
	(set #copyicon "Copying DeepX icons")
	(set #copycat "Copying DeepX catalogs")
	(set #icon "Select icons type")
	(set #col4 "4-color icons (Normal)")
	(set #col8 "8-color icons (MagicWB)")
))

(if (= @language "polski")
(	(set #drawer "Wybierz szufladë, do której skopiowaê DeepXa")
	(set #copy "Kopiujë DeepXa")
	(set #copyicon "Kopiujë ikony DeepXa")
	(set #copycat "Kopiujë katalogi DeepXa")
	(set #icon "Wybierz rodzaj ikon")
	(set #col4 "4-kolorowe ikony (Normalne)")
	(set #col8 "8-kolorowe ikony (MagicWB)")
))

(if (= @language "français")
(	(set #drawer "Choisir un répertoire où copier DeepX")
	(set #copy "Copie de DeepX")
	(set #copyicon "Copie des icônes de DeepX")
	(set #copycat "Copie des catalogues de DeepX")
	(set #icon "Choisir le type des icônes")
	(set #col4 "Icônes 4 couleurs (Normaux)")
	(set #col8 "Icônes 8 couleurs (MagicWB)")
))
(if (= @language "svenska")
(	(set #drawer "Välj ett bibliotek att installera DeepX till")
	(set #copy "Kopierar DeepX")
	(set #copyicon "Kopierar DeepX ikoner")
	(set #copycat "Kopierar DeepX kataloger")
	(set #icon "Välj ikon typ")
	(set #col4 "4-Färgers ikon (Normal)")
	(set #col8 "8-Färgers ikon (MagicWB)")
))

(set src (expandpath (pathonly @icon)))

(complete 0)
(set @default-dest
	(askdir
		(prompt #drawer)
		(help @askdir-help)
		(default @default-dest)
	)
)

(set man "DeepX.guide")
(if (= @language "polski") (set man "DeepX.PL.guide"))
(copyfiles
	(prompt #copy)
	(help @copyfiles-help)
	(source src)
	(dest @default-dest)
	(choices "DeepX" "DeepXPrefs" man)
)

(complete 50)
(set icons
	(askchoice
		(prompt #icon)
		(help @askchoice-help)
		(choices #col4 #col8)
	)
)

(if icons
	(copyfiles
		(prompt #copyicon)
		(help @copyfiles-help)
		(source src)
		(dest @default-dest)
		(choices "DeepX.info" "DeepXPrefs.info")
	)

	((copyfiles
		(prompt #copyicon)
		(help @copyfiles-help)
		(source (tackon src "DeepX.info.4"))
		(dest @default-dest)
		(newname "DeepX.info")
	)
	(copyfiles
		(prompt #copyicon)
		(help @copyfiles-help)
		(source (tackon src "DeepXPrefs.info.4"))
		(dest @default-dest)
		(newname "DeepXPrefs.info")
	))
)

(complete 90)
(if (NOT (= @language "english"))
	(copyfiles
		(prompt #copycat)
		(help @copyfiles-help)
		(source (cat (tackon src "Catalogs/") @language ))
		(dest (tackon "LOCALE:Catalogs" @language))
		(choices "DeepX.catalog" "DeepXPrefs.catalog")
	)
)

(complete 100)