; ImageFX GIF Modules Install Script
;
; Written by Thomas Krehbiel
;
; Copyright  1995 Nova Design, Inc.
; All Rights Reserved

(

   ;================================================================
   ; Setup
   ;================================================================

   ; script variables...

   (set versionname "2.1a")                     ; version number
   (set programname ("ImageFX %s" versionname)) ; name of program
   (set diskname1 "ImageFX_Disk1:")             ; install disk name
   (set diskname2 "ImageFX_Disk2:")             ; second install disk name
   (set diskname3 "ImageFX_Disk3:")             ; third install disk name
   (set diskname4 "ImageFX_Disk4:")             ; fourth install disk name
   (set pdiskname1 "")                          ; patch install disk name

   (set tempdir "T:")

   ; system information...

   (set osver (/ (getversion) 65536))        ; os version
   (set cputype (database "cpu"))            ; cpu type

   ;-------------------
   ; Pick a default directory for the installation...
   (set initialdir @default-dest)            ; defaults to biggest drive
   (if (getassign "ImageFX")
      (
         (set initialdir (getassign "ImageFX"))
      )
      ; else
      (
         (if (getassign "ImageFX2")
            (
               (set initialdir (getassign "ImageFX2"))
               ; if we found ImageFX2:, assume user wants to keep ImageFX2:
               (set assignname "ImageFX2")
            )
         )
      )
   )

   (set tryagain 1)
   (while tryagain
      (

         (set tryagain 0)

         ;-------------------
         ; Ask where to install it...
         ;(set wheredir initialdir)
         (set wheredir
            (askdir
               (prompt "Select the directory where ImageFX is currently installed.  The GIF loader "
                       "and saver modules will be installed into this directory.")
               (help @askdir-help)
               (default initialdir)
            )
         )

         ;-------------------
         ; Make sure it's a valid ImageFX
         (set checkvar 0)
         (set checkvar (+ checkvar (exists (tackon wheredir "Modules/Loaders/ILBM"))))
         (set checkvar (+ checkvar (exists (tackon wheredir "ImageFX"))))
         (set checkvar (+ checkvar (exists (tackon wheredir "Modules/Savers/ILBM"))))
         (if (<> 3 checkvar)
            (
               (message "`" wheredir "' does not appear to contain a copy of ImageFX.")
               (set tryagain 1)
               (set initialdir wheredir)
            )
         )

      )
   )

   (message "The GIF modules will be installed in the drawer `" wheredir "'.  If this is correct, click `Proceed'.")

   (set @default-dest wheredir)

   ;================================================================
   ; INSTALL NEW FILES
   ;================================================================

   (working "Installing GIF modules...")

   (copyfiles
      (prompt "")
      (help "")
      (source "Modules/Loaders")
      (dest (tackon wheredir "Modules/Loaders"))
      (choices
         "GIF"
      )
   )

   (copyfiles
      (prompt "")
      (help "")
      (source "Modules/Savers")
      (dest (tackon wheredir "Modules/Savers"))
      (choices
         "GIF"
      )
   )

   ; Installation complete!
)

; Revision History:
;
;  10.10.95 tek   Created.
