;Install script for Adagis v3.1
;Š 1996 Stv
;(Hope it works !)
;
;Install the main program
;
(set directory
	(askdir
		(prompt "Where do you want Adagis to be installed ?\n(no drawer will be created)")
		(help @askdir-help)
		(default "Sys:WBStartUp")
	)
)
(copyfiles
	(prompt "Copy Adagis program:")
	(help @copyfiles-help)
	(dest directory)
	(source "/Adagis")
	(infos)
)
;
;Install Adagis.data
;
(set quinfitxer
	(askchoice
		(help @askchoice-help)
		(prompt "Which Adagis.data install ?\n\nANY PREVIOUS ADAGIS.DATA WILL BE DELETED\n")
		(choices "English" "Catalan" "Spanish" "None")
		(default 0)
	)
)
(if (<> 3 quinfitxer)			; Delete file if required
	(delete "s:adagis.data"
		(help @delete-help)
		(prompt "Delete existing Adagis.data")
	)
)
(select quinfitxer
	(copyfiles
		(prompt "Copy Adagis.data.eng file")
		(help @copyfiles-help)
		(dest "S:")
		(source "/s/Adagis.data.eng")
		(newname "s:Adagis.data")
	)
	(copyfiles
		(prompt "Copy Adagis.data.cat file")
		(help @copyfiles-help)
		(dest "S:")
		(source "/s/Adagis.data.cat")
		(newname "s:Adagis.data")
	)
	(copyfiles
		(prompt "Copy Adagis.data.espfile")
		(help @copyfiles-help)
		(dest "S:")
		(source "/s/Adagis.data.esp")
		(newname "s:Adagis.data")
	)
	(message "\n\n\nPlease, remember that Adagis requires\nan Adagis.data file in S:\n"
			 "\n\nIf you create your own file (see docs),\nplease contact the author.\n")
)
;
;Install locale files
;
(set locales
	(askoptions
		(prompt "Which catalogs do you want me to install ?")
		(help @askoptions-help)
		(choices "Spanish" "Catalan")
		(default 00)
	)
)
(if (in locales 0)
	(copyfiles
		(source "/locale/catalogs/espaņol/adagis.catalog")
		(dest "locale:catalogs/espaņol/")
		(prompt "Copying Spanish catalogs")
		(help @copyfiles-help)
	)
)
(if (in locales 1)
	(copyfiles
		(source "/locale/catalogs/catalā/adagis.catalog")
		(dest "locale:catalogs/catalā/")
		(prompt "Copying Catalan catalogs")
		(help @copyfiles-help)
	)
)