/*******************************************************/
/* MakeGuide.rexx   $VER: 1.0 (18.03.96)  for PicView  */
/* (C) 1996 Maik Solf          solf@madhouse.boerde.de */
/* Im collecting handdrawn pictures, contact me 2 swap */
/*******************************************************/

OPTIONS RESULTS
ADDRESS 'PICVIEW.1'

/* open rexxreqtools.library */
IF ~SHOW('L',"rexxreqtools.library") THEN
   IF ~ADDLIB("rexxreqtools.library", 0, -30, 0) THEN
      EXIT 10

/* Vars */
Enter='0a'x
DEnter=Enter || Enter

/* User-Options */
YourName='Maik Solf'
DefDir='RAM:'
Titel=Enter || '         @{b}Pictures from' YourName || Enter || '         -----------------------@{ub}' || Enter

/* number of pictures */
getentries
Number=RESULT
IF Number=0 THEN DO
   rtezrequest('No pictures in current catalog.' , , 'MakeGuide.rexx' )
   EXIT 5
END

/* get filename */
Filename=rtfilerequest(DefDir, , "Select File" , , , )

/* open file */
IF OPEN(Handle,Filename,'W')=0 THEN DO
   rtezrequest('Couldnt open file.' , , 'MakeGuide.rexx' )
   EXIT 20
END

/* write guide-head and titel */
Head='@database "Pictures"' || Enter || '@master "' || Filename || '"' || Enter || '@author "' || YourName || '"' || DEnter || '@node "Main" "MyPictures"'
WRITELN(Handle,Head)
WRITELN(Handle,Titel)

DO i=0 TO Number-1
/* get names of picture */
   getpicdata i data name
   Centername=CENTER(RESULT,34)
   line='    ' || '@{"' || Centername || '" link "' || RESULT || '" 0}'
   WRITELN(Handle,line)
END
WRITELN(Handle,'@endnode'||Enter)

DO i=0 TO Number-1
/* get data of picture */
   /* no parse because Space */
   getpicdata i data name
   NA=RESULT
   getpicdata i data path
   PA=RESULT
   getpicdata i data file
   FI=RESULT
   getpicdata i data comment
   CM=RESULT
   getpicdata i data modetext
   MT=RESULT
   /* parse possible */
   getpicdata i data weekday date time width height depth size format modeid
   PARSE VAR RESULT WD DA TI WI HE DP SI FM MI
/* convert to output */
   CALL UP_Format
/* write to Guide */
    Line='@node "' || NA || '" "' || NA || '"' || DEnter
    WRITELN(Handle,Line||Entry||'@endnode'||Enter)
END

CLOSE(handle)

IF Number=1
   THEN Ende=Number 'picture saved as Guide.'
   ELSE Ende=Number 'pictures saved as Guide.'

rtezrequest(Ende , , 'MakeGuide.rexx' )

EXIT 0

UP_Format:
/* chance your output */
    Entry=''
    Entry=Entry || '  Name   :' NA || Enter
    Entry=Entry || '  Width  :' WI || Enter
    Entry=Entry || '  Height :' HE || Enter
    Entry=Entry || '  Depth  :' DP || Enter
    Entry=Entry || '  Size   :' SI || Enter
    Entry=Entry || '  Mode   :' MT || Enter
RETURN