/* $VER: 0.9, ©1993 Dietmar Eilert. Fold block (use PASCAL comments).  */

OPTIONS RESULTS                             /* enable return codes     */

if (LEFT(ADDRESS(), 6) ~= "GOLDED") then    /* not started by GoldEd ? */
    address 'GOLDED.1'

'LOCK CURRENT'                              /* lock GUI, gain access   */
OPTIONS FAILAT 6                            /* ignore warnings         */
SIGNAL ON SYNTAX                            /* ensure clean exit       */

/* ------------------------ INSERT YOUR CODE HERE: ------------------- */

'GOTO BFIRST'

if (RC = 0) then do

    'QUERY CAT'

    if (RESULT = "deutsch") then
        'REQUEST STRING TITLE "Kommentar für Faltung ?" VAR NAME'
    else if (RESULT = "français")
        'REQUEST STRING TITLE "Commentaire pour ce pli ?" VAR NAME'
    else
        'REQUEST STRING TITLE "Comment for this fold ?" VAR NAME'

    NAME = '*"' || NAME || '*"'
    HEAD = '{ /// ' || CENTER(' ' || NAME || ' ', 74, '-') || ' }'

    'FIRST'
    'INSERT LINE'
    'TEXT STAY T="' || HEAD || '"'
    'DOWN'
    'INSERT LINE'
    'GOTO BLAST'
    'DOWN'
    'INSERT LINE'
    'DOWN'
    'INSERT LINE'
    'TEXT STAY T="{ /// ------------------------------------------------------------------------ }"'
    'UP'
    'FOLD'
end

/* ---------------------------- END OF YOUR CODE --------------------- */

'UNLOCK' /* VERY important: unlock GUI */
EXIT

SYNTAX:

SAY "Sorry, error line" SIGL ":" ERRORTEXT(RC) ":-("
'UNLOCK'
EXIT