ViewWindow 1,127,127,1,63,63
ClrText
Cls
Text 1,1,"NIBBLES     V:333     (C)SG'97":Text 10,1,"SCHWER  ->1":Text 17,1,"MITTEL  ->2":Text 24,1,"LEICHT  ->3"
Text 40,1,"STEUERUNG MIT PFEILTASTEN"
Text 48,1,"0 FUER PAUSE"
Text 56,1,"EXIT FUER SCHLUSS"
Do
GetKey->A
Text 32,1,"SCHWIERIGKEIT"
Text 32,1,"               "
LpWhile A<>72 And A<>62 And A<>52
Int (A/10)-6->P
1->A~O
150->J:1->D
35->G~H
Seq(X,X,1,136,1)->List 1
Do
Fill(9,List 1)
List 1->List 2
1->D
Cls
Green Vertical 1
Green Vertical 127
Green Horizontal 1
Green Horizontal 63
Green Horizontal 54
1->A
0->B
0->L
3->E
1->F
1->I
30->M~N
Text 4,4,"SCORE:"
Text 4,70,"PIXELWERT":Text 4,114,I
For P->C To 1
For P->O To 1
Orange PxlOn G+C,H+O
Next
Next
D->D
If D=2
Then Green F-Line 30,30,90,30
Else If D=3
Then For 25->Q To 100 Step 25
Green F-Line Q,15,Q,45
Next
Else If D=4
Then Green F-Line 40,28,80,28:Green F-Line 30,15,30,40:Green F-Line 100,15,100,40:Green F-Line 30,15,60,15:Green F-Line 70,15,100,15:Green F-Line 30,40,60,40:Green F-Line 70,40,100,40
Else If D=5
Then For 1->Q To 127 Step 2
Green PxlOn 45,Q
Green PxlOn 25,Q
Next
Else If D=6
Then F-Line 64,1,64,24
F-Line 63,26,63,54
F-Line 1,24,62,24
F-Line 66,25,127,25
Else If D=7
Then F-Line 30,30,60,40
F-Line 52,41,69,21
F-Line 40,20,10,20
F-Line 20,40,20,10
F-Line 60,69,21,41
4->D
IfEnd
IfEnd
IfEnd
IfEnd
IfEnd
Do
J-1->J
M+A->M
N+B->N
If J<=0
Then Locate 1,1,"HUNGERTOD"
ClrList
Stop
IfEnd
For P->C To 1
If M=(H+C)
Then For P->O To 1
If N=(G+O)
Then For P->C To 1
For P->O To 1
PxlOff G+C,H+O
Next
Next
Do
0->Q
12+Int (48Ran#)->G:12+Int (110Ran#)->H
For P->C To 1
For P->O To 1
PxlTest G+C,H+O
If Ans=1
Then 1->Q
IfEnd
Next
Next
LpWhile Q=1
For P->C To 1
For P->O To 1
Orange PxlOn G+C,H+O
Next
Next
J+200->J
For E+1->Q To E+3I
9->List 1[Q]
9->List 2[Q]
Next
3I+E->E
I+1->I
If I=9
Then D+1->D
700+J->J
1->L
Else Text 4,114,I
IfEnd
IfEnd
Next
IfEnd
Next
PxlTest N,M
If Ans=1
Then 1->L
0->D
IfEnd
If F>=E
Then 1->F
Else 1+F->F
IfEnd
PxlOff List 1[F],List 2[F]
N->List 1[F]
M->List 2[F]
Blue PxlOn N,M
GetKey->K
If K=27
Then 1->A:0->B
Else If K=38
Then (-)1->A:0->B
Else If K=28
Then 0->A:(-)1->B
Else If K=37
Then 0->A:1->B
Else If K=71
Then Do
Text 4,4,"PAUSE EXE FUER WEITER"
Text 4,4,"                              "
LpWhile GetKey<>31
Text 4,4,"SCORE:"
Text 4,70,"PIXELWERT"
Text 4,114,I
IfEnd:IfEnd:IfEnd:IfEnd:IfEnd
If Frac (J/10)=0
Then Text 4,30,"     "
Text 4,30,J*(P+2)
IfEnd
LpWhile (K<>47) And (L<>1)
LpWhile (D<>0) And (K<>47)
If K<>47
Then Locate 1,1,"ANGESTOSSEN"
Else Locate 1,1,"ABBRUCH"
IfEnd
ClrList
Locate 1,2,"PUNKTE:"
Locate 8,2,J*(P+2)
Locate 1,4,"AC DRUECKEN UM AUFZU(-)"
Locate 1,5,"HOEREN"
Locate 1,6,"EXE DRUEKEN UM"
Locate 1,7,"NOCHMAL ZU SPIELEN"