.bra {
.ket }
.key REQUEST/S,KEEPONLINE/S,STEP/S,TIMES/F


; /*     $VER: MailCheck 1.45 (28.04.98)      */
; /*                                          */
; /*   e-mail retreival with Miami and YAM    */
; /*                                          */
; /*  This script is part of MailCheck v1.45  */
; /*    and may not be modified or copied     */
; /*  without the authors written permission  */
; /*                                          */
; /*  ©1997-98 DCS Software by Robert Wilson  */


failat 25 

if exists s:user-startup
  search s:user-startup "SetEnv MCStep" >nil:
  if not warn
    if exists c:requestchoice
      c:requestchoice >env:answer "Error" "Please remove the line beginning*n'SetEnv MCStep'*nfrom your user-startup!" "Sorry"
    else
      echo "Please remove the line beginning 'SetEnv MCStep' from your user-startup!"       
    endif
  skip END
  endif
endif

assign >nil: Miami: EXISTS
if warn 
  echo "MailCheck needs an assign to the Miami directory"
  skip END
endif

assign >nil: YAM: EXISTS
if warn 
  echo "MailCheck needs an assign to the YAM directory"
  skip END
endif

assign >nil: MailCheck: EXISTS
if warn 
  echo "The MailCheck directory needs to be assigned"
  skip END
endif

if exists MailCheck:MailCheck.config
  search MailCheck:MailCheck.config "CHECKMODEM" >nil:
  if warn 
    c:requestchoice >env:answer "Error" "Your v1.3 config file needs updating!*nPlease read the docs for more info." "Sorry"
    quit
  endif
  search MailCheck:MailCheck.config "MAXWARN" >nil:
  if warn 
    c:requestchoice >env:answer "Error" "Your v1.3.1 config file needs updating!*nPlease read the docs for more info." "Sorry"
    quit
  endif
else
  c:requestchoice >env:answer "Error" "Cannot find your MailCheck config file!" "Hmmm"
  quit
endif

if $MCMailRun eq "1"
  skip VERYEND
else
  setenv MCMailRun 1
endif

if not exists libs:rexxsupport.library
  echo "MailCheck requires rexxsupport.library"
  skip END
endif

if not exists libs:reqtools.library
  echo "MailCheck requires reqtools.library"
  skip END
endif

if not exists libs:rexxreqtools.library
  echo "MailCheck requires rexxreqtools.library"
  skip END
endif

if not exists libs:rexxtricks.library
  echo "MailCheck requires rexxtricks.library"
  skip END
endif

if not exists MailCheck:C/OkayDokey
  echo "Can't find OkayDokey in MailCheck:C/"
  skip END
endif

if not exists MailCheck:C/Wait
  echo "Can't find Wait in MailCheck:C/"
  skip END
endif

if not exists c:CheckModem
  echo "Can't find CheckModem in Sys:C/"
  skip END
endif

if not exists c:InputStream
  echo "Can't find InputStream in Sys:C/"
  skip END
endif

if exists env:mcplayer 
  if not exists $mcplayer
    echo "Can't find $mcplayer"
    skip END
  endif
else
  if not exists c:Play16
    echo "Can't find Play16 in Sys:C/"
    skip END
  endif
endif

if not exists Miami:Miami
  echo "Can't find Miami in Miami:"
  skip END
endif

if not exists YAM:YAM
  echo "Can't find YAM in YAM:"
  skip END
endif

if not exists Env:MCStep
  setenv MCStep 1
else
  if $MCStep eq "0"
    setenv MCStep 1
  endif
endif

if {STEP} eq "STEP"
  setenv MCStepValue 2
endif

if val {TIMES} ge "2"
  setenv MCStepValue {TIMES}
endif
 
if val {TIMES} not ge "2"
  if {STEP} not eq "STEP"
    setenv MCStepValue 1 
  endif
endif

if val $MCStep not ge $MCStepValue
  eval $MCStep + 1 to Env:MCstep
  sys:rexxc/rx >nil: MailCheck:Rexx/MailCheck.rexx ALWAYS
  if $RC eq 5
    skip END
  endif
endif

if {REQUEST} eq "REQUEST"
  sys:rexxc/rx >nil: MailCheck:Rexx/MailCheck.rexx REQUEST
  if $RC eq 5 
    skip END
  endif
endif

setenv MCMaxTime 0
setenv MCReturn 0

if {KEEPONLINE} eq "KEEPONLINE"
  sys:rexxc/rx MailCheck:Rexx/MailCheck.rexx KEEPONLINE
else
  sys:rexxc/rx MailCheck:Rexx/MailCheck.rexx
endif


if $MCReturn eq 0
  if exists MailCheck:User_Scripts/User_Script_07
    execute MailCheck:User_Scripts/User_Script_07
  endif
else
  setenv MCStep 1  
endif

lab WriteLog

sys:rexxc/rx 'say d2c(09)' >env:tab

echo "$MCDay$tab$MCDate$tab$MCTime$tab$MCDuration$tab$MCIn$tab$MCOut$tab$MCMessage" >> MailCheck:MailCheck.log

if exists MailCheck:User_Scripts/User_Script_08
  execute MailCheck:User_Scripts/User_Script_08
endif

lab END

setenv MCMailRun 0

lab VERYEND

quit