; /*    $VER: EditConfig 1.45 (28.04.98)      */
; /*                                          */
; /*  This script is part of MailCheck v1.45  */
; /*    and may not be modified or copied     */
; /*  without the authors written permission  */
; /*                                          */
; /*  ©1997-98 DCS Softwate by Robert Wilson  */


if $MCEditRun eq "1"
  sys:rexxc/rx 'say show(P,EDITCONFIG)' >env:tempvar
  if $tempvar eq "1"
    sys:rexxc/rx 'address MCEDIT show'
  else
    c:requestchoice >env:answer "Error" "MailCheck Prefs is already running!" "Okay"  
  endif
  delete env:tempvar QUIET
  skip END
else
  setenv MCEditRun 1
endif

if $MCMailRun eq "1"
  c:requestchoice >env:answer "Sorry" "MailCheck is still at work." "Okay"  
  setenv MCEditRun 0
  skip END
endif

if not exists libs:reqtools.library
  echo "EditConfig requires reqtools.library"
  setenv MCEditRun 0
  skip END
endif

if not exists libs:rexxreqtools.library
  echo "EditConfig requires rexxreqtools.library"
  setenv MCEditRun 0
  skip END
endif

if not exists libs:rexxtricks.library
  echo "EditConfig requires rexxtricks.library"
  setenv MCEditRun 0
  skip END
endif

assign >nil: MUI: exists
if not warn
  if not exists MUI:Libs/MUI/Icon.mcc
    echo "EditConfig requires icon.mcc in MUI:libs/MUI/ - this file is distributed with MUIRexx!!!"
    setenv MCEditRun 0
    skip END
  endif
else
  echo "EditConfig requires MUI v3.0 or higher"
  setenv MCEditRun 0
  skip END
endif

assign >nil: MUIRexx: EXISTS
if warn
  c:requestchoice >env:answer "Error!" "This programs requires MUIRexx v3.0*nor higher installed on your Amiga." "Sorry"  
  setenv MCEditRun 0
  skip END
else
  if exists muirexx:muirexx
    version >nil: muirexx:muirexx 3
    if warn
      c:requestchoice >env:answer "Error!" "This programs requires MUIRexx v3.0*nor higher. It will not work with v2.2." "Sorry"  
      setenv MCEditRun 0
      skip END
    endif
  endif
endif

search mailcheck:mailcheck.config "MAXWARN" >nil:
if warn 
  c:requestchoice >env:answer "Error" "Your MailCheck config file*nneeds updating to v1.4." "Okay"
  setenv MCEditRun 0
  skip END
endif

stack 20000

if exists muirexx:muirexx
   muirexx:muirexx MailCheck:rexx/EditConfigGUI.rexx PORT MCEDIT HELP MailCheck:docs/MailCheck.guide ;>nil:
else
   muirexx MailCheck:rexx/EditConfigGUI.rexx PORT MCEDIT HELP MailCheck:docs/MailCheck.guide ;>nil:
endif

setenv MCEditRun 0

lab END

quit