(set #dirname		"MagicReader")

(if (= @language "suomi")
	(
	(set #destdir-prompt "Minne haluat asentaa ohjelman? Uusi hakemisto luodaan nimeltä 'MagicReader'.")
	(set #verchoice-prompt "Valitse prosessorisi tyyppi?")
	(set #catchoice-prompt "Mitkä kielet haluat asentaa?")
	(set #copylibs-prompt "Kopioidaan ulkoiset MUI-luokat.")
	(set #copy-texteditor-mcc-prompt "Asennetaan TextEditor.mcc.")
	(set #copy-texteditor-mcp-prompt "Asennetaan TextEditor.mcp.")
	(set #copy-toolbar-mcc-prompt "Asennetaan ToolBar.mcc.")
	(set #copy-toolbar-mcp-prompt "Asennetaan ToolBar.mcp.")
	)

;	English

	(
	(set #destdir-prompt "Where should MagicReader be installed? A drawer named 'MagicReader' will be created there.")
	(set #verchoice-prompt "Please select your processor?")
	(set #catchoice-prompt "Which languages do you want to install?")
	(set #copy-texteditor-mcc-prompt "Installing TextEditor.mcc.")
	(set #copy-texteditor-mcp-prompt "Installing TextEditor.mcp.")
	(set #copy-toolbar-mcc-prompt "Installing ToolBar.mcc.")
	(set #copy-toolbar-mcp-prompt "Installing ToolBar.mcp.")
	)
)

(set @default-dest
	(askdir
		(prompt	#destdir-prompt)
		(help @makedir-help)
		(disk)
		(default "")
		(newpath)
	)
)

(set @default-dest
	(tackon @default-dest #dirname)
)
(set #catalogs
	(tackon @default-dest "Catalogs")
)

(makedir @default-dest
	(infos)
)

(complete 10)

(set	#version
	(askchoice
	(prompt	#verchoice-prompt)
	(help	@askchoice-help)
	(choices "000/010" "020/030/040/060")
	)
)

(if (= #version 0)
	(
		(copyfiles
			(source "MagicReader_000")
			(dest	@default-dest)
			(newname "MagicReader")
		)
	)

	(
		(copyfiles
			(source "MagicReader_020")
			(dest	@default-dest)
			(newname "MagicReader")
		)
	)

)

(complete 20)

(copyfiles
	(source "")
	(dest	@default-dest)
	(pattern "MagicReader.#?")
)

(complete 30)

(copyfiles
	(source "")
	(dest	@default-dest)
	(pattern "Images")
	(nogauge)
)

(makedir #catalogs)

(complete 40)

(copyfiles
	(source "Catalogs")
	(dest	#catalogs)
	(pattern "magicreader.cd")
	(nogauge)
)

(complete 50)

(copyfiles
	(prompt #catchoice-prompt)
	(help	@askchoice-help)
	(source "Catalogs")
	(dest	#catalogs)
	(choices "Suomi" "Deutsch")
	(nogauge)
	(confirm)
)

(complete 60)

(copylib
	(prompt	#copy-texteditor-mcc-prompt)
	(help	@copylib-help)
	(source	"Libs/MUI/TextEditor.mcc")
	(dest	"MUI:Libs/MUI")
	(optional nofail)
	(confirm)
)

(complete 70)

(copylib
	(prompt	#copy-texteditor-mcp-prompt)
	(help	@copylib-help)
	(source	"Libs/MUI/TextEditor.mcp")
	(dest	"MUI:Libs/MUI")
	(optional nofail)
	(confirm "expert")
)

(complete 80)

(copylib
	(prompt	#copy-toolbar-mcc-prompt)
	(help	@copylib-help)
	(source	"Libs/MUI/ToolBar.mcc")
	(dest	"MUI:Libs/MUI")
	(optional nofail)
	(confirm "expert")
)

(complete 90)

(copylib
	(prompt	#copy-toolbar-mcp-prompt)
	(help	@copylib-help)
	(source	"Libs/MUI/ToolBar.mcp")
	(dest	"MUI:Libs/MUI")
	(optional nofail)
	(confirm "expert")
)

(complete 100)