;/* install script version 1.1
; * $VER: BCInstall 1.1 (10-02-98)
; */


(set #inst_text "BackClock Installation on Hard Disk")
(set #prog "backclock")
(set @minuser "Intermediate")
(set @appname "BackClock")
(set #gosrc      1)
(set #gobootup   1)
(set #defpathprefs "sys:prefs/")


(set #destdir_prompt "Where do you want to install BackClock\nA drawer will be created.")
(set #destdirprefs   "Where do you want to install BackClock preferences.")

(set #destdir (askdir
    (prompt #destdir_prompt)
    (help @askdir-help)
    (default "Work:")
  )
)

(set @default-dest (tackon #destdir "BackClock"))
(if (not (exists (@default-dest)))
  (makedir @default-dest (infos))
)
(if (>= @user-level 1)
  (set #gobootup
    (askbool
      (prompt "Do you want to run BackClock each startup ?")
      (help   "If you answer yes, then BackClock will be copied to SYS:WBStartup.")
    )
  )
)

(set #sourcepath @default-dest)

(if (>= @user-level 1)
  (set #defpathprefs (askdir
    (prompt #destdirprefs)
    (help   "Please choose where to place the preferences utility.")
    (default #defpathprefs)
    )
  )
)
(if (>= @user-level 1)
  (if (askbool
        (prompt "Do you want to install sources ?")
        (help   "This will install the sources of the program in the directory sources./")
      )
      (
        ;install sources
        (set #gosrc 1)
        (if (= 2 @user-level)
          (
            (set #sourcepath (askdir
                (prompt "Where do you want to install sources codes ?\nA drawer called sources will be created there.")
                (help   "You have to choose where the sources be placed.")
                (default @default-dest)
              )
            )
          )
        )
      )
      ; don't install sources
      (set #gosrc 0)
  )
)

(if (= 1 #gosrc)
  ((if (not (exists (tackon #sourcepath "sources")))
               (makedir (tackon #sourcepath "sources"))
            )
  )
)

(copyfiles
  (prompt "Copying Main file")
  (help   "Copy the executable and the icon of the main file in the path you choosed")
  (source "bin/")
  (dest   @default-dest)
  (all)
)
(copyfiles
  (prompt "Copying preferences program")
  (help   "Copy the preferences executable and the icon file in the path you choosed")
  (source "prefs/")
  (dest   #defpathprefs)
  (all)
)

(copyfiles
  (prompt "Cpying documentation")
  (help   "Copy the documentation in the path you choosed")
  (source "docs/backclock.guide")
  (dest   @default-dest)
  (infos)
)

(if (= 1 #gobootup)
  (copyfiles
    (prompt "Copying to WBStartup")
    (help   "Copy the executable file to wbstartup\nThis will run BackClock each reboot.")
    (source "bin/backclock")
    (dest   "SYS:WBstartup/")
    (infos)
  )
)

(if (= 1 #gosrc)
  (copyfiles
    (prompt "Copying sources")
    (help   "Copy the sources in C in the the path you choosed")
    (source "sources/")
    (dest   (tackon #sourcepath "sources"))
    (all)
  )
)