/*
 *  Script Arexx di esempio per Televideo
 *  
 *      Scritto da Piergiorgio Ghezzo
 *
 *
 *  Il seguente script trasmette una pagina tramite
 *  AmIRC. Se non e' selezionata una pagina viene
 *  trasmessa quella attualmente caricata.
 *
 */

OPTIONS RESULTS
ADDRESS TELEVIDEO.1

PARSE ARG NuovaPagina Dest .

GETPAGESTEM Pagina NuovaPagina

/*** La variabile Pagina.NUM ora contiene il numero della pagina caricata ***/
/*** La variabile Pagina.0 contiene invece il numero di linee             ***/
/*** Il testo della pagina e' contenuto nello stem Pagina.x               ***/

SAY "Ho letto la pagina" Pagina.NUM
SAY "Nella pagina ci sono" Pagina.0 "linee."


/*** Ora mando il contenuto della pagina su IRC ***/

IF Dest ~= ""
   THEN DO
        ADDRESS AMIRC.1 "ECHO P=«Televideo» Spedisco pagina" Pagina.NUM "a" Dest
        ADDRESS AMIRC.1 "RAW PRIVMSG" Dest ":+- << TELEVIDEO by PJ >> ------ Pag." Pagina.NUM "-+"
        END
   ELSE ADDRESS AMIRC.1 SAY "+- << TELEVIDEO by PJ >> ------ Pag." Pagina.NUM "-+"

Ciclo = 2
Flood = 1

DO WHILE Ciclo <= Pagina.0

   IF Dest ~= ""
      THEN ADDRESS AMIRC.1 "RAW PRIVMSG" Dest ":|"||LEFT(Pagina.Ciclo,40)||" |"
      ELSE ADDRESS AMIRC.1 SAY "|"||LEFT(Pagina.Ciclo,40)||" |"

   Ciclo = Ciclo + 1

   /*** Con questi ritardi evito le uscite per flood ***/
   Flood = Flood + 1
   IF Flood //  3 = 0 THEN ADDRESS COMMAND "C:Wait 1"
   IF Flood //  6 = 0 THEN ADDRESS COMMAND "C:Wait 2"
   IF Flood // 12 = 0 THEN ADDRESS COMMAND "C:Wait 4"
   END


IF Dest ~= ""
   THEN ADDRESS AMIRC.1 "RAW PRIVMSG" Dest ":+-----------------------------------------+"
   ELSE ADDRESS AMIRC.1 SAY "+-----------------------------------------+"