; Duenix
; Installation Script - 5/9/97

(set LANG
	(askchoice
		(prompt " Select the language of the game\nZvol jazyk hry")
		(help @askchoice-help)	
		(choices "English   =   AngliÃtina" "Czech     =   ãeÓtina")
		(default 0)
	)
)

(if (= LANG 0)
   (
	(set WHERE_TO_INSTALL  "Where do you wish to install Duenix?\n")
	(set NEW_DIR_CREATED "A directory named 'Duenix' will be created there")
	(set INSERT_DUENIX "Please insert volume Duenix:")
	(set CHECKING_VER "Checking version of ")
	(set COPYING_AMOS_LIB "Copying amos.library\n  (really strange 'library')")
	(set INSTALLING_DATA "Installing data files")
	(set INSTALLING_FONT "Installing font")
   )
)

(if (= LANG 1)
   (
	(set WHERE_TO_INSTALL  "Kam si prejeÓ Duenix nainstalovat?\n")
	(set NEW_DIR_CREATED "Bude zde vytvoÒen adresÁÒ 'Duenix'")
	(set INSERT_DUENIX "VloÚ prosÉm disk Duenix:")
	(set CHECKING_VER "OvÅÒuji verzi ")
	(set COPYING_AMOS_LIB "KopÉruji amos.library\n  (podivnÁ 'knihovna')")
	(set INSTALLING_DATA "Installuji datov× soubory")
	(set INSTALLING_FONT "Installuji font")
   )
)

(if (= @default-dest "Duenix:")
   (set @default-dest "Ram:")
)
(set MAINPATH
	(askdir
		(prompt WHERE_TO_INSTALL NEW_DIR_CREATED)
		(help @askdir-help)
		(default @default-dest)
		(newpath)
	)
)

(set MAINPATH (tackon MAINPATH "Duenix"))
(makedir MAINPATH(infos))

(set @default-dest MAINPATH)

(copylib
	(prompt CHECKING_VER "diskfont.library" )
	(help @copylib-help)
	(source "libs/diskfont.library")
	(dest "libs:")
	(confirm)
)

(copylib
	(prompt CHECKING_VER "mathtrans.library")
	(help @copylib-help)
	(source "libs/mathtrans.library")
	(dest "libs:")
	(confirm)
)

(complete 7)

(copyfiles
	(prompt COPYING_AMOS_LIB)
	(help @copyfiles-help)
	(source "libs/amos.library")
	(dest "libs:")
	(confirm)
)

(complete 10)

(copyfiles
	(prompt INSTALLING_DATA)
	(source "Dx")
	(help @copyfiles-help)
	(dest MAINPATH)
	(all)
)

(complete 95)

(copyfiles
	(prompt INSTALLING_FONT)
	(source "Fonts")
	(help @copyfiles-help)
	(dest "Fonts:")
	(all)
)

(if (= LANG 0)
 (
  (copyfiles
	(prompt "Localizing")
	(source "Dx/english_files")
	(pattern "Duenix_Language")
        (help @copyfiles-help)	
	(dest MAINPATH)
  )
  (copyfiles
	(prompt "Localizing")
	(source "")
	(pattern "Duenix_Guide#?")
        (help @copyfiles-help)	
	(dest MAINPATH)
  )
 )
)

(if (= LANG 1)
 (
  (copyfiles
	(prompt "Lokalizuji")
	(source "Dx/czech_files")
	(pattern "Duenix_Language")
        (help @copyfiles-help)	
	(dest MAINPATH)
  )
  (copyfiles
	(prompt "Lokalizuji")
	(source "")
	(pattern "Duenix_Pruvodce#?")
        (help @copyfiles-help)	
	(dest MAINPATH)
  )
 )
)


(complete 100)

(exit)