; $VER: Install_TaskForce 1.02 (09.03.98)

(complete 0)

; version check
(if (< (/ (getversion) 65536) 37)
    (abort "You must be using Kickstart 2.04 or higher to run TaskForce.")
)

(welcome)

(set @default-dest
	(askdir
		(prompt "Please choose a directory where to install the game. A directory named \"TaskForce\" will be created.")
		(help @askdir-help)
		(default @default-dest)
	)
)

(complete 15)

(set #instdir (tackon @default-dest "TaskForce") )

(makedir #instdir (infos))
(makedir (tackon #instdir "Games"))
(makedir (tackon #instdir "Missions"))
(makedir (tackon #instdir "Missions/OnePlayer"))
(makedir (tackon #instdir "Missions/TwoPlayers"))
(makedir (tackon #instdir "Briefings"))

(complete 25)

(if (< @user-level 2)
	(set #missions 1)
	(set #missions
		(askoptions
			(prompt "Select the missions you wish to install.")
			(help (cat
				"The mission files are needed to play TaskForce. "
				"Each mission introduces new characters, defines "
				"different goals, and is generally a different "
				"experience. It is recommended to copy all files. "
				"However, you may opt not to install all available "
				"missions because of low harddisk space, for example "
				"(rather improbable, isn't it?).\n"
				"The number in brackets indicates whether it is a "
				"scenario for one or two human players."
			))
			(choices "Urban Combat (2)")
			(default 1)
		)
	)
)

(complete 30)

(copyfiles
	(prompt "Copying game files...")
	(help @copyfiles-help)
	(source "")
	(dest #instdir)
	(choices "TaskForce" "Editor" "Data" "Docs" "Briefings.info")
	(infos)
)

(complete 65)

(working "\n\n\nTaskForce is now installing the mission files...")

(set n 0)
(while
	(set #missionfiles
		(select n
			"TwoPlayers/Urban Combat"
			""
		)
	)
(
	(if (IN #missions n)
		(
		    (copyfiles
				(source "Missions/")
				(dest (tackon #instdir "Missions"))
				(choices (cat #missionfiles ".mission"))
				(nogauge)
			)
			(copyfiles
				(source "Briefings/")
				(dest (tackon #instdir "Briefings"))
				(choices (fileonly #missionfiles))
				(infos)
				(nogauge)
			)
		)
	)
	(set n (+ n 1))
))

(complete 90)

(copylib
	(prompt "Installing reqtools.library")
	(help @copylib-help)
	(source "Libs/reqtools.library")
	(dest "LIBS:")
	(confirm)
)
	
(complete 100)