'Breakout Sample files.. 
'Fast and Simple.
'(c) 1996, Power Programs
Dim SAM$(13),SAM(13,2)
Global SAM$(),SAM(),SAMTOTAL
SAMTOTAL=0
Screen Open 0,640,256,8,Hires
For I=1 To 13
   SAMINFO[I]
Next 
Reserve As Chip Work 5,SAMTOTAL+500
SAMGET
SAMLIST
Erase 5
Procedure SAMINFO[SAMNR]
   SAM$(SAMNR)=Fsel$("Breakout_2:Samples/*.raw","*.raw","Select A Game","Sample!")
   Open In 1,SAM$(SAMNR)
   If SAMNR>1 Then SAM(SAMNR,0)=SAM(SAMNR-1,1) Else SAM(SAMNR,0)=0
   SAM(SAMNR,1)=SAM(SAMNR,0)+Lof(1)
   SAMTOTAL=SAMTOTAL+Lof(1)
   Close 1
   Cls 0 : Paper 0 : Pen 2 : Locate 0,0
   Print "Sample :";SAMNR;".  "
   Print "Name:";SAM$(SAMNR)
   Print "Length :";SAM(SAMNR,1)-SAM(SAMNR,0);" Bytes.      "
   PRTYPE[SAMNR]
   Locate 0,10
   Input "Enter sample frequency, in Hz:";SAM(SAMNR,2)
End Proc
Procedure SAMGET
   For SAM=1 To 13
      If SAM>1 Then BG=Start(5)+SAM(SAM,0) Else BG=Start(5)
      Bload SAM$(SAM),BG
   Next 
   Bsave "Breakout:Samples/In_Game.Raw",Start(5) To Start(5)+SAMTOTAL
End Proc
Procedure SAMLIST
   Open Out 1,"Breakout:Samples/In_Game.lst"
   Print #1,"SAM_LIST:"
   For I=1 To 13
      Print #1,"Sam:"+Str$(SAM(I,0))+":"+Str$(SAM(I,1))+":"+Str$(SAM(I,2))
   Next 
   Print #1,"END."
   Close 1
End Proc
Procedure PRTYPE[SAMNR]
   Restore SAMTYPE
   For I=1 To SAMNR
      Read TYPE$
   Next 
   Print "Sample Description:";TYPE$
   Pop Proc
   SAMTYPE:
   Data "Get Ready music. (looped)"
   Data "Bounce-sound 1. (Paddle)"
   Data "Bounce-sound 2. (Bricks)"
   Data "Bounce-sound 3. (Walls)"
   Data "Brick destroyed 1. (Single hit)"
   Data "Brick destroyed 2. (Multi hit)"
   Data "Bonus sound 1. (Point-bonus sound)"
   Data "Bonus sound 2. (Other-bonus sound)"
   Data "MiniGun."
   Data "MegaGun."
   Data "Electric Zapping sound. (In Death/Appear Sequence)"
   Data "Explosion (Your Death). (repeated)"
   Data "Groovy (Extra Life). (Bonus-Sound)"
End Proc