; Installer script for PrintManager V1.1, © 1997-1998 by Stephan Rupprecht

;--- localize strings ----
(if (= @language "deutsch")
(
	(set #wrongver "PrintManager benötigt mindestens AmigaOS3.0.\nInstallation kann nicht durchgeführt werden.")
	(set #askdir_prompt "Bitte wählen Sie das Zielverzeichnis für den PrintManager")
)
(
	(set #wrongver "PrintManager requires at least AmigaOS3.0\nInstallation aborted.")
	(set #askdir_prompt "Please select the drawer where PrintManger should be installed")
)
)

;--- check os version ---
(set #vernum (getversion "exec.library" (resident)))
(set #vernum (/ #vernum 65536))

(if(< #vernum 39)
	(abort #wrongver)
)

;--- copy main program ---
(set @default-dest
	(askdir
		(prompt #askdir_prompt)
		(help @askdir-help)
		(default "SYS:WBStartup")
	)
)

(copyfiles
	(help @copyfiles-help)
	(source "PrintManager")
	(dest @default-dest)
)

(set #info_path (cat @default-dest "/" "PrintManager.info") )

(message #info_path)

(if (not (exists #info_path) )
	(copyfiles
		(help @copyfiles-help)
		(source "PrintManager.info")
		(dest @default-dest)
	)
)

;--- copy spool.device ---
(copyfiles
	(help @copyfiles-help)
	(source "devs/spool.device")
	(dest "devs:")
)

;--- install printer port file (prt.dev v42 only) ---
;(set #vernum (getversion "devs:printer.device"))
;(set #vernum (/ #vernum 65536))

;(if(= #vernum 42)
;	(copyfiles
;		(help @copyfiles-help)
;		(source "PrinterPorts/Spool.info")
;		(dest "devs:PrinterPorts/")
;	)
;)

;--- copy catalog ---
(if (NOT (= @language "english")) 
(
	(set #src_name
		(cat "Catalogs/" @language "/")
	)

	(set #dst_name
		(cat "LOCALE:" #src_name)
	)

	(set #src_name
		(cat #src_name "printmanager.catalog")
	)

	(if (exists #src_name (noreq))
	(
		(copyfiles
			(help @copyfiles-help)
			(source #src_name)
			(dest #dst_name)
		)
	)
		(message "Sorry, there is no " @language " catalog available at the moment!")
	) 
)
)
;--- eof ---