;$VER: Install UFO 1.0 (10-05-1994)
;UFO Hard Drive Installation Script

(complete 0)

;=============================================================================

(set #ask-UFO-dir-ENG
	(cat
		"In which disk or drawer should a drawer \"UFO\" "
		"be created where all files will be copied?"
	)
)

(set #ask-UFO-dir-help-ENG
	(cat
		"Here you specify, where you want to install UFO "
		"and all support files. A drawer \"UFO\" will "
		"be created, so you select \"DH0:\" to install UFO "
		"in a drawer \"DH0:UFO\".\n\n"
	)
)

(set #ask-UFO-bool-1200-ENG
	"\nWill you be running UFO from hard disk\non a 2 meg A1200?"
)

(set #ask-UFO-mesg-1200-ENG
	(cat
		"\n"
		"Although UFO can be run from your hard disk, "
		"it will need to be intially booted from floppy disk "
		"so that the maximum amount of memory will be available."
		"\n\n"
		"This installation will create a boot disk for you."
	)
)

(set #ask-UFO-mesg-insert-ENG
	(cat
		"\n"
		"Please insert a floppy disk to be formatted\ninto drive DF0:"
	)
)

(set #ask-UFO-working-formatting-ENG
	(cat
		"\n"
		"Formatting disk in drive DF0:\nPlease wait...."
	)
)

(set #ask-UFO-copying-ENG
	(cat
		"\n"
		"Copying UFO files...."
	)
)

;=============================================================================

(set #ask-UFO-dir-FRE
	(cat
		"Dans quel disque ou tiroir devrait être créé UFO?  Tous les fichiers "
		"seront copiés à cet endroit."
	)
)

(set #ask-UFO-dir-help-FRE
	(cat
		"Veuillez spécifier la destination pour l'installation d'UFO et des "
		"fichiers de soutien.  Un tiroir intitulé UFO sera créé.\n\n"
	)
)

(set #ask-UFO-bool-1200-FRE
	(cat
		"\n"
		"Allez-vous lancer UFO à partir du disque\ndur d'un A1200 de 2 Mo?"
	)
)

(set #ask-UFO-mesg-1200-FRE
	(cat
		"\n"
		"Bien qu'UFO puisse être lancé à partir du disque dur, vous devrez "
		"initialement le booter à partir d'une disquette pour permettre une "
		"utilisation maximum de la mémoire.\n\n"
		"Cette installation créera une disquette de boot pour vous."
	)
)

(set #ask-UFO-mesg-insert-FRE
	(cat
		"\n"
		"Veuillez insérer une disquette à formater dans le lecteur DF0:"
	)
)

(set #ask-UFO-working-formatting-FRE
	(cat
		"\n"
		"Formatage de la disquette se trouvant dans le lecteur DF0:\nVeuillez patienter...."
	)
)

(set #ask-UFO-copying-FRE
	(cat
		"\n"
		"Copie des fichiers d'UFO..."
	)
)

;=============================================================================

(set #ask-UFO-dir-GER
	(cat
		"In welchem Laufwerk oder welcher Schublade soll UFO installiert "
		"werden?  Dorthin werden alle Dateien übertragen."
	)
)

(set #ask-UFO-dir-help-GER
	(cat
		"Bitte angeben, wo UFO und Zusatzdateien installiert werden sollen.  Eine "
		"Schublade namens UFO wird dann erstellt.\n\n"
	)
)

(set #ask-UFO-bool-1200-GER
	(cat
		"\n"
		"Wollen Sie UFO von der Festplatte eines\nA1200 mit 2 MB betreiben?"
	)
)

(set #ask-UFO-mesg-1200-GER
	(cat
		"\n"
		"UFO kann zwar von der Festplatte betrieben werden, muß aber zunächst "
		"von einer Diskette gebootet werden, um maximale Speichernutzung zu "
		"gewährleisten.  Diese Installation erstellt eine Bootdiskette für Sie."
	)
)

(set #ask-UFO-mesg-insert-GER
	(cat
		"\n"
		"Bitte eine Diskette zur Formatierung in Laufwerk DF0: einlegen."
	)
)

(set #ask-UFO-working-formatting-GER
	(cat
		"\n"
		"Diskette in Laufwerk DF0: wird formatiert.\nBitte warten..."
	)
)

(set #ask-UFO-copying-GER
	(cat
		"\n"
		"UFO-Dateien werden kopiert..."
	)
)

;=============================================================================
;=============================================================================
;=============================================================================

;Ask for destination drawer or partition for UFO

(set language
	(askchoice
		(prompt "")
		(help
			@askchoice-help
		)
		(choices "English" "Français" "Deutsch")
	)
)

(if (= language 0)
	(
		(set #ask-UFO-dir #ask-UFO-dir-ENG)
		(set #ask-UFO-dir-help #ask-UFO-dir-help-ENG)
		(set #ask-UFO-bool-1200 #ask-UFO-bool-1200-ENG)
		(set #ask-UFO-mesg-1200 #ask-UFO-mesg-1200-ENG)
		(set #ask-UFO-mesg-insert #ask-UFO-mesg-insert-ENG)
		(set #ask-UFO-working-formatting #ask-UFO-working-formatting-ENG)
		(set #ask-UFO-copying #ask-UFO-copying-ENG)
		(set #ask-UFO-diskfull #ask-UFO-diskfull-ENG)
	)
)
(if (= language 1)
	(
		(set #ask-UFO-dir #ask-UFO-dir-FRE)
		(set #ask-UFO-dir-help #ask-UFO-dir-help-FRE)
		(set #ask-UFO-bool-1200 #ask-UFO-bool-1200-FRE)
		(set #ask-UFO-mesg-1200 #ask-UFO-mesg-1200-FRE)
		(set #ask-UFO-mesg-insert #ask-UFO-mesg-insert-FRE)
		(set #ask-UFO-working-formatting #ask-UFO-working-formatting-FRE)
		(set #ask-UFO-copying #ask-UFO-copying-FRE)
		(set #ask-UFO-diskfull #ask-UFO-diskfull-FRE)
	)
)
(if (= language 2)
	(
		(set #ask-UFO-dir #ask-UFO-dir-GER)
		(set #ask-UFO-dir-help #ask-UFO-dir-help-GER)
		(set #ask-UFO-bool-1200 #ask-UFO-bool-1200-GER)
		(set #ask-UFO-mesg-1200 #ask-UFO-mesg-1200-GER)
		(set #ask-UFO-mesg-insert #ask-UFO-mesg-insert-GER)
		(set #ask-UFO-working-formatting #ask-UFO-working-formatting-GER)
		(set #ask-UFO-copying #ask-UFO-copying-GER)
		(set #ask-UFO-diskfull #ask-UFO-diskfull-GER)
	)
)

(set UFO_dest
	(tackon
		(askdir
			(prompt #ask-UFO-dir)
			(help
				#ask-UFO-dir-help
				@askdir-help
			)
			(default "Work:")
		)
		"UFO"
	)
)
(set @default-dest UFO_dest)
(complete 10)




(if
	(askbool
		(prompt #ask-UFO-bool-1200)
		(help @askbool-help )
	)
	(
		(message #ask-UFO-mesg-1200)

		(copyfiles
			(source "UFO Disk 3:")
			(dest "ram:")
			(pattern "CR")
			(nogauge)
			(help @copyfiles-help)
		)

		(message #ask-UFO-mesg-insert)
		(working #ask-UFO-working-formatting)
		(while
			(run "sys:system/format <ram:CR drive df0: name UFO_Boot_Disk noicons ffs")
			(
				(message #ask-UFO-mesg-insert)
				(working #ask-UFO-working-formatting)
			)
		)
		(run "c:install df0: ffs")
		(copyfiles
			(source "UFO Disk 1:c")
			(dest "ram:temp")
			(nogauge)
			(all)
			(help @copyfiles-help)
		)
		(copyfiles
			(source "ram:temp")
			(dest "UFO_Boot_Disk:c")
			(nogauge)
			(all)
			(help @copyfiles-help)
		)
		(makedir "UFO_Boot_Disk:s")
		(textfile
			(dest "UFO_Boot_Disk:s/startup-sequence")
			(append
				(cat "Assign >NIL: <NIL: T: Ram:\n"
				     "Assign >NIL: <NIL: LOCALE: " UFO_Dest "\n"
				     "Assign >NIL: <NIL: Libs: " UFO_Dest "/libs\n"
				     "Assign >NIL: <NIL: Fonts: " UFO_Dest "/fonts\n"
				     "Assign >NIL: <NIL: ENV: Ram:\n"
				     "Assign >NIL: <NIL: UfoTemp: Ram:\n"
				     "SetPatch >NIL: <NIL: Quiet\n"
				     "Cd >NIL: <NIL: " UFO_Dest "\n"
				     "Execute >NIL: <NIL: " UFO_Dest "/UFO\n"
				)
			)
		)
	)
)



(working #ask-UFO-copying)

(makedir UFO_dest
	(infos)
)

(complete 20)



;Copy all the program files from disk 1 to dest

(copyfiles
	(source "UFO Disk 3:")
	(dest UFO_dest)
	(pattern "~((Install)#?)")
	(infos)
	(help @copyfiles-help)
)

(complete 40)



;Copy all the program files from disk 2 to dest

(copyfiles
	(source "UFO Disk 4:")
	(dest UFO_dest)
	(pattern "~((Install)#?)")
	(infos)
	(help @copyfiles-help)
)

(complete 60)



;Copy all the program files from disk 3 to dest

(copyfiles
	(source "UFO Disk 2:")
	(dest UFO_dest)
	(pattern "~((Install)#?)")
	(infos)
	(help @copyfiles-help)
)

(complete 80)



;Copy all the program files from disk 4 to dest

(copyfiles
	(source "UFO Disk 1:")
	(dest UFO_dest)
	(pattern "~((Install)#?)")
	(infos)
	(help @copyfiles-help)
)

(complete 90)



(delete (cat UFO_dest "/UFO")
	(help @delete-help)
)
(rename (cat UFO_dest "/UFO_HD") (cat UFO_dest "/UFO")
	(help @rename-help)
)
(rename (cat UFO_dest "/UFO.inf") (cat UFO_dest "/UFO.info")
	(help @rename-help)
)
(protect (cat UFO_dest "/UFO") "+s")

(complete 91)


(makedir (cat UFO_dest "/MissDat") )

(complete 92)



(makedir (cat UFO_dest "/Game_2") )
(copyfiles
	(source (cat UFO_dest "/Game_1") )
	(dest (cat UFO_dest "/Game_2") )
	(nogauge)
	(all)
	(help @copyfiles-help)
)

(complete 93)

(makedir (cat UFO_dest "/Game_3") )
(copyfiles
	(source (cat UFO_dest "/Game_1") )
	(dest (cat UFO_dest "/Game_3") )
	(nogauge)
	(all)
	(help @copyfiles-help)
)

(complete 95)

(makedir (cat UFO_dest "/Game_4") )
(copyfiles
	(source (cat UFO_dest "/Game_1") )
	(dest (cat UFO_dest "/Game_4") )
	(nogauge)
	(all)
	(help @copyfiles-help)
)

(complete 97)

(makedir (cat UFO_dest "/Game_5") )
(copyfiles
	(source (cat UFO_dest "/Game_1") )
	(dest (cat UFO_dest "/Game_5") )
	(nogauge)
	(all)
	(help @copyfiles-help)
)

(complete 100)



(exit)