/* UndElEtE - kleines Tool zum undeleten auf AFS-Partitionen, das auf meiner Kiste nicht abstürzt 
wie diese MUI-Klamotte aus dem Aminet :(
Written in E³
r@((e 97
*/

OPT OSVERSION=37

MODULE 'dos/dos','dos/dosextens','reqtools','libraries/reqtools'

DEF ver,filereq:PTR TO rtfilerequester,filename[108]:STRING,volume[15]:STRING,filelist:PTR TO rtfilelist,
copystring[66]:STRING,protectstring[33]:STRING
-> 66 = 6+15+1+20+5+17+1+1 = 'Copy "' + volume + '/' + filelist.name + '" "T:' + filelist.name-4 + '"' + Nullbyte
-> 33 = 10+17+5+1 = 'Protect "T:' + filelist.name-4 + '" +WD' + Nullbyte

PROC main()
	ver:='$VER: UndElEtE 1.0 (15.9.97) by r@((e'

	IF reqtoolsbase:=OpenLibrary('reqtools.library',38)
		IF filereq:=RtAllocRequestA(RT_FILEREQ,NIL)
			WriteF('\s\n',ver+6)
			IF RtFileRequestA(filereq,filename,'Please choose an AFS-Partition',[RTFI_VOLUMEREQUEST,VREQF_NOASSIGNS,0])
				StrCopy(volume,filereq.dir,ALL)
				StrAdd(volume,'.deldir',ALL)
				RtFreeRequest(filereq)
				IF filereq:=RtAllocRequestA(RT_FILEREQ,NIL)
					RtChangeReqAttrA(filereq,[RTFI_DIR,volume,0])
					IF (filelist:=RtFileRequestA(filereq,filename,'Please choose some deleted files',[RTFI_FLAGS,FREQF_MULTISELECT OR FREQF_PATGAD,0]))
						WriteF('\nUndElEtE log:\n\n')
						REPEAT
							StrCopy(copystring,'Copy "',ALL)
							StrAdd(copystring,volume,ALL)
							StrAdd(copystring,'/',ALL)
							StrAdd(copystring,filelist.name,ALL)
							StrAdd(copystring,'" "T:',ALL)
							StrAdd(copystring,filelist.name,StrLen(filelist.name)-4)
							StrAdd(copystring,'"',ALL)
							WriteF('\s\n',copystring)
							SystemTagList(copystring,NIL)
							StrCopy(protectstring,'Protect "T:',ALL)
							StrAdd(protectstring,filelist.name,StrLen(filelist.name)-4)
							StrAdd(protectstring,'" +WD',ALL)
							WriteF('\s\n',protectstring)
							SystemTagList(protectstring,NIL)
							filelist:=filelist.next
						UNTIL filelist = NIL
						WriteF('\nDone.\n')
						RtFreeRequest(filereq)
					ENDIF
				ENDIF
			ENDIF
		ENDIF
		CloseLibrary(reqtoolsbase)
	ENDIF
ENDPROC