/* This script makes the process of updating older icons with MagicWB icons
very easy for Directory-Opus users. Remarks: IconUpdate has to be in the C:
directory. First, select the older icons to be changed. Second, select the
source MagicWB-Icon and then activate the ARexx-script by clicking on the
appropriate button (has to be configured by the user first). Have fun! */


ADDRESS 'DOPUS.1'
OPTIONS RESULTS
CHECKABORT
BUSY ON


STATUS 3
window = RESULT
STATUS 9 window
anzahl = RESULT
'STATUS 13 -1'
path_source = RESULT


IF anzahl > 1 THEN DO
  TOPTEXT 'ERROR: More than ONE MagicWB-Icon can NOT be selected as source icon!'
  BEEP
  BUSY OFF
  EXIT
END


GETSELECTEDFILES
files_a = RESULT

IF files_a = 'RESULT' THEN DO
 TOPTEXT 'ERROR: You have to specify BOTH source and destination icons!'
 BEEP
 BUSY OFF
 EXIT
END


PARSE VAR files_a icon_new files_a


OTHERWINDOW


STATUS 3
window = RESULT
STATUS 9 window
anzahl = RESULT+1
'STATUS 13 -1'
path_destination = RESULT



GETSELECTEDFILES
files_b = RESULT

IF files_b = "RESULT" THEN DO
 TOPTEXT 'ERROR: You have to specify BOTH source and destination icons!'
 BEEP
 BUSY OFF
 EXIT
END


n = anzahl
DO UNTIL n = 1
    CHECKABORT
    ergebnis = RESULT
    IF ergebnis = 1 THEN DO
    TOPTEXT 'Operation ABORTED by user!'
    BUSY OFF
    EXIT
    END
  n = n-1
  PARSE VAR files_b icon_old.n files_b

  TOPTEXT 'Updating old icon ->' icon_old.n 'with ->' icon_new

  ADDRESS COMMAND IconUpdate TCSDNW path_source||icon_new path_destination||icon_old.n
END


STATUS 3
window = RESULT
RESCAN window

OTHERWINDOW

BUSY OFF