(set #wrongversion
  (cat "You have an old version of the program 'Installer' "
       "on your Amiga!\n\nThe installation procedure needs at least Installer 42.9.\n\n"
       "Please check your configuration!"
  )
)

(set #welcome
  (cat "Welcome to the Installation of Lupe V1.8!\n\n"
       "Copyright by Frank Toepper of\n"
       "Digital Innovations."
  )
)

(set #destdir
  (cat "Select a directory to copy Lupe to.\n"
       "No directory will be created."
  )
)

(set #copystr (cat "Copying Lupe..."))

(set #askdoc
   (cat "Do you want to install the documentation?")
)

(set #docdir
  (cat "Select a directory for documentation.")
)

(set #copydoc
  (cat "Copying documentation...")
)

(set #cat
   (cat "Which catalog file(s) do you want to install\n(english is build in)?")
)

(set #askicon
   (cat "Do you want to install the Appicon?")
)

; We can't handle this script without Installer 42.9 or better!
(if (< @installer-version 2752521)
  (
    ; Big problem!
    (message #wrongversion)
    (exit (quiet))
  )
)

(welcome #welcome)

(set destdir
 (askdir
  (prompt #destdir)
  (help @askdir-help)
  (default "SYS:")
 )
)

(if (patmatch "68000|68010" (database "cpu"))
  ((set #srcname "Lupe"))
  ;else
  ((set #srcname "Lupe.020"))
) ;if

(copyfiles
  (prompt #copystr)
  (help @copyfiles-help)
  (source #srcname)
  (dest destdir)
  (files)
  (newname "Lupe")
  (optional force)
)

(copyfiles
  (prompt #copystr)
  (help @copyfiles-help)
  (source "Lupe.info")
  (dest destdir)
  (noposition)
  (optional force)
)

(set docbool
  (askbool
    (prompt #askdoc)
    (choices "Yes" "No")
    (help "No Help!")
    (default 0)
  )
)

(if (= docbool 1)
(
 (set docdir
  (askdir
  (prompt #docdir)
  (help @askdir-help)
  (default "Help:")
 )
)

(set docfiles
 (askoptions
  (prompt "Which documentation do you want to install?")
  (help @askoptions-help)
  (choices "English" "Deutsch")
  (default 1)
 )
)

(if (BITAND docfiles 1)
  (copyfiles
  (prompt "Copy documentation...")
  (help @copyfiles-help)
  (dest docdir)
  (source "Lupe.doc")
  (files)
  (infos)
  )
)

(if (BITAND docfiles 2)
  (copyfiles
  (prompt "Copy documentation...")
  (help @copyfiles-help)
  (dest docdir)
  (source "Lupe.dok")
  (files)
  (infos)
  )
)
)) ; if

(copyfiles
  (prompt #cat)
  (help @copyfiles-help)
  (source "locale/catalogs")
  (dest "Locale:catalogs")
  (pattern "#?")
  (confirm)
)

(set iconbool
  (askbool
    (prompt #askicon)
    (choices "Yes" "No")
    (help "No Help!")
    (default 0)
  )
)

(if (= iconbool 1)
(
  (copyfiles
  (prompt "Copy Appicon...")
  (help @copyfiles-help)
  (dest "Envarc:sys")
  (source "Prefs/Env-Archive/sys/def_Lupe.info")
  (files)
  )
  (copyfiles
  (prompt "Copy Appicon...")
  (help @copyfiles-help)
  (dest "Env:sys")
  (source "Prefs/Env-Archive/sys/def_Lupe.info")
  (files)
  )
)
)