; $VER: mFinger installer 0.2 (5.5.97)
; by Remco van Hooff
; localized by Sönke Tesch/ATO
; ============================================================================
;
; init =======================================================================

; english defaults

(set InstallingFile ("Installing \"%s\"."))
(set WelcomeMsg "\n\n\nThis installer script will install mFinger %s and the needed MUI classes.")
(set NoMui "You don't seem to have MUI installed.")
(set DestDirRequest "Where do you want to install mFinger?\nNo directory will be created.")
(set DestDirHelp "Select a directory where you want to place mFinger and it's documentation.")
(set LanguageRequest "What language(s) would you like to install ?\nEnglish is the built-in language.")
(set LanguageHelp "This will install locale files for other languages than English.")
(set ARexxRequest "\n\nDo you want to install mFinger.amirx?\nIt's an AmIRC ARexx script to finger someone using mFinger.")
(set ARexxHelp " Install an optional ARexx script that will enable you to use mFinger from AmIRC?")
(set RexxDestRequest "Where should the script be installed?")
(set RexxDestHelp "Install the script in the rexx directory of AmIRC.")

; german (December 1996 Sönke Tesch/ATO)

(if (= @language "deutsch")
  (
  (set InstallingFile ("Installiere \"%s\"."))
  (set WelcomeMsg "\n\n\nMit diesem Script werden mFinger %s und die nötigen MUI Klassen installiert.")
  (set NoMui "Du hast MUI anscheinend nicht installiert?!")
  (set DestDirRequest "Wohin soll mFinger kopiert werden?\nEs wird kein extra Verzeichniss angelegt.")
  (set DestDirHelp "Such dir ein Verzeichniss aus, in das mFinger und die Anleitung kopiert werden soll.")
  (set LanguageRequest "Welche Sprache(n) soll(en) installiert werden?\nEnglisch ist bereits eingebaut.")
  (set LanguageHelp "Hier können andere Sprachen für mFinger installiert werden.")
  (set ARexxRequest "\n\nSoll mFinger.amirx installiert werden?\nEs ist ein Script für AmIRC, um andere Leute zu fingern.")
  (set ARexxHelp " Dieses ARexx-Script für AmIRC ermöglicht es, von AmIRC aus mFinger zu benutzen.\nSoll es installiert werden?")
  (set RexxDestRequest "Wohin soll mFinger.amirc kopiert werden?")
  (set RexxDestHelp "Das Script sollte in das rexx-Verzeichniss von AmIRC kopiert werden.")
  )
)

;
(set mfver "1.2")
(set destdir "Work:")
(set catdir "catalogs")

; define procedures ==========================================================

(procedure installmf
   (copyfiles
      (prompt (InstallingFile file))
      (help @copyfiles-help)
      (source file)
      (dest destdir)
   )
)

(procedure installmf2
   (copylib
      (prompt (InstallingFile file))
      (help @copyfiles-help)
      (source file)
      (dest "Mui:libs/mui")
   )
)

; msg ========================================================================

(Welcome (WelcomeMsg mfver))

; install the MUI classes ====================================================

(set mui (exists "mui:"))
(if (= mui 2)
    (
     (set file "Libs/mui/NList.mcc")
     (installmf2)

     (set file "Libs/mui/NListview.mcc")
     (installmf2)

     (set file "Libs/mui/NListviews.mcp")
     (installmf2)
    )
    (abort NoMui)
)

; select dest dir ============================================================

(set destdir
    (askdir
       (prompt DestDirRequest)
       (help DestDirHelp)
       (default destdir )
    )
)
(set @default-dest destdir)

; copy the mFinger files =====================================================

(set file "mFinger")
(installmf)

(set file "mFinger.info")
(installmf)

(set file "mFinger.addresses")
(installmf)

(set file "mFinger.guide")
(installmf)

(set file "mFinger.guide.info")
(installmf)

; install catalogs ===========================================================
(set catalog
   (askoptions
          (prompt LanguageRequest)
          (help LanguageHelp)
      (choices "Dansk" "Deutsch" "Italiano" "Norsk" "Polski" "Slovenski" "Suomi" "Svenska" "ÃeÓtina")
      (default 0)
   )
)

(set catdir (tackon destdir catdir))
(makedir catdir)

(if (bitand 1 catalog)
   (copylib
      (source "Catalogs/dansk/mfinger.catalog")
      (dest (tackon catdir "dansk"))
   )
)

(if (bitand 2 catalog)
   (copylib
      (source "Catalogs/deutsch/mfinger.catalog")
      (dest (tackon catdir "deutsch"))
   )
)

(if (bitand 4 catalog)
   (copylib
      (source "Catalogs/italiano/mfinger.catalog")
      (dest (tackon catdir "italiano"))
   )
)

(if (bitand 8 catalog)
   (copylib
      (source "Catalogs/norsk/mfinger.catalog")
      (dest (tackon catdir "norsk"))
   )
)

(if (bitand 16 catalog)
   (copylib
      (source "Catalogs/polski/mfinger.catalog")
      (dest (tackon catdir "polski"))
   )
)

(if (bitand 32 catalog)
   (copylib
      (source "Catalogs/slovenski/mfinger.catalog")
      (dest (tackon catdir "slovenski"))
   )
)

(if (bitand 64 catalog)
   (copylib
      (source "Catalogs/svenska/mfinger.catalog")
      (dest (tackon catdir "suomi"))
   )
)

(if (bitand 128 catalog)
   (copylib
      (source "Catalogs/svenska/mfinger.catalog")
      (dest (tackon catdir "svenska"))
   )
)

(if (bitand 256 catalog)
   (copylib
      (source "Catalogs/ÃeÓtina/mfinger.catalog")
      (dest (tackon catdir "ÃeÓtina"))
   )
)

; install optional AmIRC script ==============================================

(if
  (askbool
    (prompt ARexxRequest)
    (help ARexxHelp)
  )
  ((set destdir
      (askdir
        (prompt RexxDestRequest)
        (help RexxDestHelp)
        (default "s:")
      )
   )
   ((set file "Rexx/mFinger.AMIRX")
    (installmf)
   )
  )
)

(exit)