; VER$="Installer script for ThumbMail V1.0"
; ------------------------------------------
;
; 24.6.95 by Alexander Reifinger
;

(set @app-name "ThumbMail V1.0")


;=============================================================================
; English strings

(set default_lang 4)

(set #welcomestring
	(cat "    ThumbMail V1.0\n    --------------\n\n1995 by Christian Buchner\n      "
	     "& Alexander Reifinger\n\nShareware: 10 DM (10 US-$, 70 AS, 10 SF)\n"
	)
)

(set #whereprogram "Where should I place the ThumbMail program?")
(set #wherehelp "If you don't want ThumbMail to be started on every bootup, you may want to change the suggested path and start ThumbMail manually when needed.")
(set #copyprogram "Now copying the main program.")
(set #copylib "Should I install the screennotify.library by Stefan Becker? This library is needed and it is recommended to install it now!")
(set #copylibhelp "This library allows us to open our window on a foreign screen without disturbing it when it closes.")
(set #extractinglib "Extracting screennotify.library...")
(set #copyinglib "Copying scrennotify.library...")
(set #wheredoc "Where should I place the ThumbMail documentation?")
(set #wheredochelp "It will be best to copy the Documentation to the Amigaguide search path, e.g. to Help: or Amigaguide:, so that the online help (not yet implemented) will find the guide.")
(set #copydoc "Now copying the documentation in AmigaGuide-Format.")
(set #copydocpics "Now copying the pictures belonging to the guide.")
(set #whichpics "What kind of pictures do you want to install?")
(set #whichpicshelp
	(cat "Users of Amigas with the old Chipset (A500, A600, A2000, A3000) without graphics adaptor should select the grayscale pictures."
	     "\nFor those using an Amiga that is equipped with the AGA-Chipset (A1200, A4000) it is simply a question of patience whether to select the grayscale or color pictures, the color pics look cute on a 32 color display, but using a 32 color screen will slow down your system quite a bit. As a proud owner of a gfx-card you should in any case select the color pictures."
	)
)
(set #picchoice1 "4 colors grayscale")
(set #picchoice2 "32 colors")
(set #wherepics "Where should I copy the pics to?\nYOU MUST CREATE A DRAWER (ANY NAME POSSIBLE)!")
(set #wherepicshelp "All pictures are copied in here.")
(set #extract1 "Now extracting the grayscale pics to ")
(set #extract2 "Now extracting the color pics to ")
(set #startup1 "Adding `Assign ThumbMail: ")
(set #startup2 "` to your User-startup.")
(set #startuphelp "In case you have a modified Startup-Sequence, this might not work. Please do add the Assign manually if this should be the case!")
(set #endmessage "Please note: Is is recommended to use a screenmode promotor for Spot and Foozle (e.g. NewMode, available on AmiNet). Use an 8 or 16 color screenmode for the Grayscale pictures. Use a 32 or 64 color screenmode for the color pictures. Have fun with ThumbMail. And Please send us your image or suggestions for improving the program (how to do that, see the documentation).")

;=============================================================================
; German strings

(if (= @language "deutsch")
	(
		(set default_lang 2)
		
		(set #whereprogram "Wohin soll ich das ThumbMail-Programm kopieren?")
		(set #wherehelp "Wenn Sie nicht wollen, da ThumbMail bei jedem Neustart aufgerufen wird, mssen Sie den vorgegebenen Pfad ndern und ThumbMail dann jedes Mal von Hand aufrufen.")
		(set #copyprogram "Ich kopiere nun das Hauptprogramm.")
		(set #copylib "Soll ich die screennotify.library von Stefan Becker installieren? Diese Library wird von ThumbMail bentigt und wir empfehlen, sie zu installieren!")
		(set #copylibhelp "Diese Library erlaubt uns, unser Fenster auf einem fremden Bildschirm zu ffnen, ohne diesen beim Schlieen zu behindern.")
		(set #extractinglib "Ich extrahiere die screennotify.library")
		(set #copyinglib "Ich kopiere die scrennotify.library")
		(set #wheredoc "Wohin soll ich die ThumbMail-Dokumentation kopieren?")
		(set #wheredochelp "Am besten kopieren Sie die Dokumentation in den Amigaguide-Suchpfad, also z.B. nach Help: oder Amigaguide:, damit die (noch nicht eingebaute) Online-Hilfe das Guide findet.")
		(set #copydoc "Ich kopiere nun die Dokumentation im AmigaGuide-Format.")
		(set #copydocpics "Ich kopiere nun die zur Dokumentation gehrenden Bilder.")
		(set #whichpics "Welche Art Bilder soll ich installieren?")
		(set #whichpicshelp
			(cat "Benutzer eines Amigas mit dem alten Chipset (A500, A600, A2000, A3000) ohne Grafikkarte sollten die Graustufen-Bilder whlen."
			     "\nAuf Amigas mit dem AGA-Chipset (A1200, A4000) ist es eine Frage der Geduld, welche Sorte Bilder Sie whlen, bei hoher Farbzahl(mindestens 32 Farben) auf dem Bildschirm des Mailers sehen zwar die 32-Farbbilder besser aus als die 4-Graustufenbilder, aber der Computer luft bei 32 Farben deutlich langsamer als bei 4 oder 8 Farben.\nBesitzer einer Grafikkarte sollten auf jeden Fall die Farbbilder whlen."
			)
		)
		(set #picchoice1 "4 Graustufen")
		(set #picchoice2 "32 Farben")
		(set #wherepics "Wohin sollen die Bilder kopiert werden?\nBITTE ERZEUGEN SIE EINE SCHUBLADE BELIEBIGEN NAMENS!")
		(set #wherepicshelp "Alle Bilder werden hier hineinkopiert.")
		(set #extract1 "Ich extrahiere nun die Graustufen-Bilder nach ")
		(set #extract2 "Ich extrahiere nun die Farb-Bilder nach ")
		(set #startup1 "Ich fge nun `Assign ThumbMail: ")
		(set #startup2 "` in die User-startup ein.")
		(set #startuphelp "Wenn Sie eine unkonforme Startup-Sequence haben, knnte dieser Befehl nicht funktionieren. Bitte fgen sie den Assign dann von Hand ein!")
		(set #endmessage "Bitte beachten Sie: Es wird empfohlen, einen Screenmode-Promoter (Bildschirm-Umlenkprogramm) fr Spot und Foozle zu verwenden (z.B. NewMode, erhltlich im AmiNet). Benutzen Sie einen 8 oder 16 Farb-Modus fr die Graustufen-Bilder oder einen 32 oder 64 Farb-Bildschirmmodus fr die Farbbilder. Viel Spa mit ThumbMail! Und bitte senden Sie uns Ihr Bild oder Verbesserungsvorschlge! (wie, steht in der Anleitung).")
	)
)

(complete 0)

(welcome #welcomestring)

(set ExeDir
	(askdir
		(prompt #whereprogram)
		(help #wherehelp)
		(default "SYS:WBStartup")
	)
)

(copyfiles
	(prompt #copyprogram)
	(source "/")
	(pattern "ThumbMail")
	(dest ExeDir)
	(infos)
)

(complete 20)

(set AskCopyLib
	(askbool
		(prompt #copylib)
		(help #copylibhelp)
		(default 1)
	)
)

(if AskCopyLib
	(
		(run "LhX e -x0 /ScreenNotify/ScreenNotify10.lha screennotify.library T:"
			(prompt #extractinglib)
			(help "")
			(safe)
		)
		(copylib
			(prompt #CopyingLib)
			(help "")
			(source "T:screennotify.library")
			(dest "Libs:")
			(confirm)
		)
		(delete "T:screennotify.library"
			(safe)
		)
	)
)

(set DocDir
	(askdir
		(prompt #wheredoc)
		(help #wheredochelp)
		(default (cat "help:" @language))
	)
)

(copyfiles
	(prompt #copydoc)
	(source "/")
	(pattern "ThumbMail.guide")
	(dest DocDir)
	(infos)
)

(complete 40)

(copyfiles
	(prompt #copydocpics)
	(source "/")
	(pattern "#?.JPG")
	(dest DocDir)
	(infos)
)

(complete 50)

(set Bilder
	(askoptions
		(prompt #whichpics)
		(help #whichpicshelp)
		(choices #picchoice1 #picchoice2)
		(default 1)
	)
)

(set PicDir
	(askdir
		(prompt #wherepics)
		(help #wherepicshelp)
		(default "Mail:")
	)
)

(if (BITAND Bilder 1)
	(
		(message #extract1 PicDir ".")
		(run "LhX e /Pics/Images_4g.lha" (cat PicDir "/"))
	)
)

(if (BITAND Bilder 2)
	(
		(message #extract2 PicDir".")
		(run "LhX e /Pics/Images_32c.lha" (cat PicDir "/"))
	)
)

(complete 90)

(startup "ThumbMail"
	(prompt #startup1 PicDir #startup2)
	(help #startuphelp)
	(command "  Assign ThumbMail: " PicDir)
)

(complete 100)

(message #endmessage)

; End of File
