/*
 * About
 *
 * USAGE: 'mui/About'(MUIPORT/A,PRGPORT/K,PRGPATH/K)
 *
 * About... :-)
 *
 * REQUIREMENTS:
 *	LIBS:rexxdossupport.library
 *	REXX:dos/ReadBlock
 *	REXX:dos/SplitPath
 *
 * $(C): (1996, Rocco Coluccelli, Bologna)
 * $VER: About 0.10 (11.Nov.1996)
 */

OPTIONS RESULTS
IF ~ReadArgs(ARG(1),"MUIPORT/A,PRGPORT/K,PRGPATH/K") THEN RETURN 0
ADDRESS VALUE muiport

IF SYMBOL('prgport') = 'LIT' THEN prgport = ""
IF SYMBOL('prgpath') = 'VAR' THEN DO
	text = _prginfo(muiport,prgport,prgpath)
	CALL 'dos/splitpath'(prgpath,'tag.METHODS="NODIR"'); END
ELSE DO
	text = _ports(muiport,prgport)
	result = "About"; END

'Request TITLE "'result'" GADGETS "_Thanks|_More" STRING' text
IF result = 1 THEN RETURN 1

text =	"\n\033c" ||,
		"\033bRocco ""the Dwarf"" Coluccelli - MOOS development\033n\033l\n\n" ||,
		" \033b __\033n                       \033b   _\033n\n" ||,
		" \033b |(\033n     rocco@inmedia.it  \033b_ //\033n  Computer Science Engineering\n" ||,
		" \033be  \033n  moos@freenet.hut.fi  \033b\\X/ \033n  \033ihttp://www.inmedia.it/Amiga\033n\n"

'Request TITLE "The Author" GADGETS "_OK" STRING' text
RETURN 1


_prginfo: PROCEDURE
	t1 = "REQUIREMENTS:"; t2 = '0a'x||" *"||'0a'x; t3 = "$(C): ("; t4 = ")"; t5 = "$VER: "; t6 = '0a'x
	PARSE VALUE 'dos/ReadBlock'(ARG(3),'tag.BYTES=4096') WITH (t1) require (t2), (t3) copyright (t4) (t5) version (t6)
	RETURN _copyright(copyright) || _version(version) || _ports(ARG(1),ARG(2)) || _require(require)

_copyright: PROCEDURE
	IF ARG(1) = "" THEN RETURN ""
	RETURN "\033b$(C):\033n\033i" ARG(1)"\033n\n"

_version: PROCEDURE
	IF ARG(1) = "" THEN RETURN ""
	RETURN "\033b$VER:\033n\033i" ARG(1)"\n\n"

_ports: PROCEDURE
PARSE ARG mui,prg
	str = "\033n\033cMUI port:\033b" mui
	IF prg = "" THEN RETURN str"\n"
	RETURN str " \033nAPP port:\033b" prg"\n"

_require: PROCEDURE
PARSE ARG txt
	IF txt = "" THEN RETURN ""
	str = "\n\033lREQUIREMENTS:\033n"
	DO UNTIL txt = ""; PARSE VAR txt "*" line '0a'x txt
		str = str"\n  "STRIP(line,,'0920'x)
	END
	RETURN str
