;
; $VER: Install_Visage 39.11 (8.12.96)
;
; Installer script for Visage.
;


(set #german-lang        1)
(set #english-lang       2)
(set #spanish-lang       4)
(set #french-lang        8)
(set #italian-lang      16)
(set #dutch-lang        32)
(set #norwegian-lang    64)
(set #russian-lang     128)
(set #serbian-lang     256)
(set #finnish-lang     512)
(set #swedish-lang    1024)

; Get current language (no need for lots of silly icons! ;). However, this
; won't properly work for all versions of the Installer. Some doesn't
; understand the language "default". :/

(if (= (exists "Env:Language") 1)
	; GetEnv reports "String too long" if the variable doesn't exist! :(
	; Dunno if this is fixed in V43... But we need the check anyway.
	(set @language (getenv "language"))
)

;**************************************************************************
;
; English strings
;


(set #default-lang #english-lang)

(set #bad-kick
	"You must have AmigaOS Release 3.0 or newer to use Visage."
)

(set #welcome
	(cat
		"\n\n\nWelcome to the Visage installation utility.\n\n"
		"This program lets you install Visage on your Amiga.\n\n\n"
		"Visage © 1995-96  Magnus Holmgren."
	)
)

(set #install-parts "Please select the parts you wish to install")

(set #item-visage "Visage")

(set #item-visage-guide "Visage.guide")

(set #item-locale "Translations")

(set #item-codec "JPEG codec")

; The following four strings are program names. Normally, these shouldn't
; be translated, though one could consider appending some locale-specific
; text after the names.

(set #item-getmodeid "GetModeID")

(set #item-kill "Kill")

(set #item-makelink "MakeLink")

(set #item-deletelink "DeleteLink")

(set #item-unpackilbm "UnpackILBM")

(set #install-parts-help
	(cat
		"    Here you select the different parts of Visage that you would like to "
		"install. After that, you select the details of the installation (such as "
		"where the different files should be installed). You may choose to install "
		"the following items:\n"
		"    Visage: The actual picture viewer.\n"
		"    Visage.guide: The manual, in AmigaGuide® format. If you install it "
		"using the installer, the text will reflow to fit the current window size. "
		"If you do a manual installation, the text is fixed to 76 columns.\n"
		"    Translations: If you install a translation, then Visage can operate in "
		"the language(s) you select.\n"
		"    JPEG codec: The Tower JPEG Codec Class, which Visage needs to be able "
		"to view JPEG pictures (without using datatypes).\n"
		"    GetModeID: A program that shows a screen mode requester, and prints "
		"a decimal number that represents the selected screen mode.\n"
		"    Kill: A program that can stop another program (sending \"break\" "
		"signals). Similar to Break.\n"
		"    MakeLink: A replacement for the MakeLink command that supports "
		"soft links.\n"
		"    DeleteLink: A simple Delete-clone that also deletes soft links "
		"without a target.\n"
		"    UnpackILBM: A program that unpacks the picture data in an IFF ILBM "
		"picture (the BODY chunk).\n"
		"    For more information about these parts, please read the manual.\n"
	)
)

(set #where-visage "Where would you like to install Visage?\nA drawer will NOT be created!")

(set #where-visage-guide "Where would you like to install Visage.guide?")

(set #copy-guide-icon "Should I copy the icon for Visage.guide?")

(set #convert-guide "Converting Visage.guide...")

(set #which-language "Which languages should be installed?")

(set #which-language-help
	(cat
		"    The Amiga can be operated in many different languages. If you "
		"want Visage to use the same language as your Amiga Workbench, "
		"then a couple of catalog files must be copied to your harddisk "
		"for each language supported.\n"
		"    To reduce the amount of space consumed by the language files, "
		"you can select to have only the files of specific languages "
		"copied.\n"
		"    Simply check the boxes of the languages you wish to have have "
		"available on your system.\n"
	)
)

(set #where-language
	(cat
		"Where do you want to install the language files?\n\n"
		"You can install them in either the same drawer as the program "
		"itself (select \"Program\") or in the 'global' volume "
		"\"Locale:\" (select \"Locale:\")."
	)
)

; These two strings must match the strings used in above in #where-language.
; The words in question are the quoted ones after "select" in the parentheses.
(set #lang-progdir "Program")

(set #lang-locale  "Locale:")

(set #where-language-help
	(cat
		"    If you install the language files in the same drawer as Visage "
		"itself (or rather, in subdirectories within that drawer), then you "
		"need to move these files as well, if you move Visage to some other "
		"drawer. If you install the language files in \"Locale:\" you don't "
		"need to worry about them if you move Visage. On the other hand, you "
		"will not have all Visage-related files in the same drawer."
	)
)

(set #builtin-lang "(default)")

(set #where-tools "Where would you like to install the extra programs?")

(set #where-tools-help
	(cat
		"    Here you specify where the programs GetModeID, Kill, MakeLink, "
		"DeleteLink and UnpackILBM will be installed. Only the programs you "
		"selected will be installed. Since these programs are Shell-only, "
		"the default location is C:, where the systems Shell-only programs "
		"can be found.\n"
		"    It is recommended that you install these programs somewhere in "
		"your command search path.\n"
	)
)

(set #copy "Copying %s to %s...")

(set #program-update "How do you want to update the tooltypes in the icon?")

(set #update-none "No update")

(set #update-all "Add all")

(set #update-since "Add new since %s")

(set #program-update-help
	(cat
		"    Since this installation updates an older version of Visage, "
		"the icon will not be copied over. This to maintain any changes "
		"you may have made to it. However, new tooltypes may have been added. "
		"Here you can decide if you want to:\n"
		"    No update: Skip this part.\n"
		"    Add all tooltypes: existing tooltypes will not be changed "
		"Any tooltypes you may have removed will be added again. The new "
		"tooltypes will be added as well.\n "
		"    Add new since 39.x: Only add the new tooltypes since that version. "
		"Any existing tooltype not be changed.\n"
	)
)

; JPEG codec

(set #codec-message
	(cat
		"\n\n\nTower JPEG Codec Class\n\nCopyright © 1994 Christoph Feck, TowerSystems\n"
		"All Rights Reserved.\n\n\n\n"
		"Please refer to the documentation for details."
	)
)

(set #jpeg-tmp-prompt
	"Select a directory for temporary files, not in RAM:"
)

(set #temp-file
	(cat
		"    To decode certain JPEG images, the Codec needs a large amount of memory.\n"
		"If the required storage is not available in main memory, the Codec will "
		"create a temporary file on your harddisk. The volume on which this file is "
		"created should have enough free space (about 4 meg).\n"
		"    A temporary file is usually only required, if you want to quantize "
		"JPEG images to 256 colors.\n\n"
		@askdir-help
	)
)

(set #jpeg-startup-prompt
	"An assignment has to be added to your user-startup."
)

(set #make-assign
	(cat
		"    The logical assignment \"JPEGTMP:\" is used to refer to the temporary "
		"directory.\n"
		"    In order to make this assignment available on every reboot, an "
		"\"Assign\" command has to be added to your \"user-startup\" file.\n\n"
		@startup-help
	)
)

(set #jpeg-copy "Copying %s...")


;**************************************************************************
;
; German strings
;

(if (= @language "deutsch")
	(
		(set #default-lang #german-lang)
	)
)


;**************************************************************************
;
; Spanish strings
;

(if (= @language "español")
	(
		(set #default-lang #spanish-lang)

		(set #bad-kick "Imprescindible SO 3.0 o superior para usar Visage.")

		(set #welcome
			(cat
				"\n\n\n Bienvenido al instalador del programa Visage.\n\n"
				"Este programa le permite instalar el visor de imágenes "
				"Visage en su Amiga.\n\n\n"
				"Visage © 1995-96  Magnus Holmgren."
			)
		)

		(set #install-parts "Por favor, elija qué partes desea instalar")

		(set #item-visage "Visage")

		(set #item-visage-guide "Visage.guide")

		(set #item-locale "Idiomas")

		(set #item-codec "JPEG codec")

		(set #item-getmodeid "GetModeID")

		(set #item-kill "Kill")

		(set #item-makelink "MakeLink")

		(set #item-unpackilbm "UnpackILBM")

		(set #install-parts-help
			(cat
				"\n   Aquí usted puede elegir las diferentes partes de "
				"Visage que deben ser instaladas; a continuación, "
				"deberá seleccionar los detalles de la instalación "
				"(como el lugar donde deben ser instalados p. ej.). "
				"Puede elegir qué elementos desea instalar o no de "
				"entre los siguientes:\n\n"
				"   Visage (el programa visualizador de imágenes).\n\n"
				"   Visage.guide (manual en formato AmigaGuide®; "
				"si lo instala desde aquí, el texto se redistribuirá "
				"para caber en el actual tamaño de ventana, mientras "
				"que si lo hace manualmente el ancho será de 76 "
				"columnas.\n\n"
				"   Catálogos (permite a Visage expresarse en el idioma "
				"que usted seleccione --de entre los disponibles-- tanto "
				"en la instalación como desde las preferencias del WB).\n\n"
				"   JPEG codec (esta clase le permite a Visage mostrar "
				"imágenes JPEG, sin tener que usar los filtros del SO "
				"--Datatypes--).\n\n"
				"   GetModeID (este programa muestra una petición de "
				"modos de pantalla para que se elija uno, e imprime el nº "
				"decimal que lo representa.\n\n"
				"   Kill (permite detener otro programa, enviando una señal "
				"\"break\": similar al comando Break del AmigaDOS.\n\n"
				"   MakeLink (sustituto del comando MakeLink del AmigaDOS "
				"que soporta vinculaciones o enlaces soft --'soft "
				"links'--).\n\n"
				"    DeleteLink: A simple Delete-clone that also deletes "
				"soft links without a target.\n\n"
				"   UnpackILBM (descomprime los datos, o sea el cuerpo o "
				"bloque BODY, de la imagen IFF ILBM señalada.\n\n"
				"   Para más información sobre lo anterior, consulte el "
				"manual.\n\n"
			)
		)

		(set #where-visage "¿Dónde desea instalar Visage?")

		(set #where-visage-guide "¿Dónde desea instalar la documentación Visage.guide?")

		(set #copy-guide-icon "¿Quiere que copie el icono de Visage.guide?")

		(set #convert-guide "Convirtiendo Visage.guide...")

		(set #which-language "¿Qué idiomas desea instalar?")

		(set #which-language-help
			(cat
				"\n    El Amiga puede trabajar con diferentes idiomas, así que "
				"si desea que Visage pueda emplear el mismo definido para su "
				"Amiga Workbench, tendrán que ser copiados los ficheros "
				"catálogo que correspondan a su disco duro (uno por cada "
				"lengua soportada).\n\n"
				"    Para reducir la cantidad de espacio consumido por estos "
				"ficheros idiomáticos, puede seleccionar únicamente los de "
				"las lenguas que desee copiar y/o instalar, bastando para "
				"ello que sólo active el interruptor de aquellos de los que "
				"quiera disponer en su sistema.\n"
			)
		)

		(set #where-tools "¿Desea que se instalen las herramientas auxiliares?")

		(set #where-tools-help
			(cat
				"\n   Aquí ha de especificar cuál(es) de los programas "
				"GetModeID, Kill, MakeLink, DeleteLink y/o UnpackILBM "
				"desea instalar: sólo los programas que usted seleccione "
				"serán copiados. Como estas utilidades son para utilizar "
				"únicamente desde el Shell, el directorio destino por "
				"defecto es C:, que es el lugar habitual donde encontrar "
				"este tipo de programas.\n\n"
				"   Es recomendable que instale estos programas en algún "
				"lugar accesible por el sistema de forma automática (use "
				"en tal caso el comando Path del AmigaDOS).\n"
			)
		)

		(set #copy "Copiando %s a %s...")

		(set #program-update "¿Quiere actualizar los tipos de herramienta del icono?")

		(set #update-none "No actualizar")

		(set #update-all "Añadir todo")

		(set #update-since "Añadir nuevo hasta %s")

		(set #program-update-help
			(cat
				"\n   Hasta esta actualización de la instalación en "
				"una versión antigua de Visage, el icono no podía "
				"ser copiado encima: esto era para mantener cualquier "
				"cambio que hubiese hecho usted en él. Sin embargo, "
				"nuevos tipos de herramienta pueden ser añadidos, así "
				"que aquí ha de decidir lo que hacer:\n\n"
				"   No actualizar: Salta esta parte.\n\n"
				"   Añadir todos los tipos de herramienta (los tipos de "
				"herramienta no se modifican; cualquiera que usted "
				"elimine, podrá ser añadido de nuevo y los nuevos tipos "
				"de herramienta pueden ser añadidos sin problemas.\n\n"
				"   Añadir nuevo hasta 39.x (sólo añade los nuevos "
				"tipos de herramienta hasta esa versión; cualquier tipo "
				"de herramienta existente no será modificado.\n"
			)
		)

		; JPEG codec

		(set #codec-message
			(cat
				"\n\n\nClase Tower JPEG Codec\n\n"
				"Copyright © 1994 Christoph Feck, TowerSystems\n"
				"Todos los derechos reservados (All Rights Reserved).\n\n\n\n"
				"Por favor, consulte la documentación para más detalles."
			)
		)

		(set #jpeg-tmp-prompt
			(cat
				"Elija un directorio para ficheros temporal (pero que "
				"no sea la unidad RAM:)"
			)
		)

		(set #temp-file
			(cat
				"\n   Para poder decodificar algunas imágenes JPEG, "
				"necesaria  una gran cantidad de memoria. Si la memoria "
				"principal no fuese suficiente, será creado un fichero "
				"temporal en su disco duro. La unidad donde éste será "
				"creado tiene que disponer de suficiente espacio libre "
				"(sobre 4 MB).\n\n"
				"   Normalmente sólo será necesario un fichero temporal, "
				"si lo que desea es reducir imágenes JPEG a 256 "
				"colores.\n\n"
				@askdir-help
			)
		)

		(set #jpeg-startup-prompt "Añadida asignación en su fichero 'user-startup'.")

		(set #make-assign
			(cat
				"\n   La asignación lógica \"JPEGTMP:\" será empleada "
				"como directorio temporal: para que esta asignación esté "
				"vigente cada vez que se reinicie el sistema, un comando "
				"\"Assign\" será añadido en su fichero \"user-startup\".\n\n"
				@startup-help
			)
		)

		(set #jpeg-copy "Copiando %s...")
	)
)


;**************************************************************************
;
; French strings
;

(if (= @language "francais")
	(
		(set #default-lang #french-lang)
	)
)


;**************************************************************************
;
; Italian strings
;

(if (= @language "italiano")
	(
		(set #default-lang #italian-lang)
	)
)


;**************************************************************************
;
; Dutch strings
;

(if (= @language "nederlands")
	(
		(set #default-lang #dutch-lang)
	)
)


;**************************************************************************
;
; Norwegian strings
;

(if (= @language "norsk")
	(
		(set #default-lang #norwegian-lang)
	)
)


;**************************************************************************
;
; Russian strings
;

(if (= @language "russian")
	(
		(set default-lang #russian-lang)

		(set #welcome
			(cat
				"\n\n\nÃíàïí îíåaêíáañû á çìðñaêþñíï îïíâïaëëú Visage.\n\n"
			        "Üña îïíâïaëëa îíæáíêçñ Áaë òðñaìíáçñû Visage ìa Áaøò Aëçâò.\n\n\n"
			        "Visage © 1995  Magnus Holmgren."
		      )
		)

		(set #install-parts
			"Îíåaêòèðña, áúàäïçñä éíëîíìäìñú, éíñíïúä Áú åäêaäñä çìðñaêçïíáañû"
		)

		(set #item-visage "Visage")

		(set #item-visage-guide "Visage.guide")

		(set #item-locale "Translations")

		(set #item-codec "JPEG codec")

		(set #item-getmodeid "GetModeID")

		(set #item-kill "Kill")

		(set #item-makelink "MakeLink")

		(set #item-unpackilbm "UnpackILBM")

		(set #install-parts-help
			(cat
				"    Æãäðû Áú ëíåäñä áúàïañû ïaæêçöìúä éíëîíìäìñú Visage ãêþ áíæëíåìíè çô "
				"çìðñaêþõçç. Îíðêä üñíâí Áú ðëíåäñä òñíöìçñû ïaæêçöìúä ãäñaêç (ìaîïçëäï, "
				"éòãa éíìéïäñìí àòãòñ ðéíîçïíáaìú ïaæêçöìúä óaèêú). Áú ëíåäñä áúàïañû "
				"ðêäãòýùçä óaèêú:\n"
				"    Visage: ðíàðñáäììí îïíâïaëëa îïíðëíñïa éaïñçìíé.\n"
				"    Visage.guide: ãíéòëäìñaõçþ á âçã-óíïëañä. Äðêç Áú æaôíñçñä ä½ òðñaìíáçñû "
				"ð çðîíêûæíáaìçäë çìðñaêþñíïa, ñí ñäéðñ àòãäñ aáñíëañçöäðéç óíïëañçïíáañûðþ "
				"îíã ñäéòùòý øçïçìò íéìa. Á ðêòöaä "ïòöìíè" çìðñaêþõçç  øçïçìa àòãäñ 76 éíêíìíé.\n"
				"    Translations: îïç çìðñaêþõçç îäïäaíãíá Visage àòãäñ ïaàíñañû "
				"ìa áúàïaììíë Áaëç þæúéä (þæúéaô).\n"
				"    JPEG codec: éêaðð Tower JPEG Codec ñïäàòäñðþ, öñíàú Visage ëíâ îíéaæúáañû "
				"éaïñçìéç á óíïëañä JPEG (àäæ çðîíêûæíáaìçþ áðñïíäììúô ñçîíá ãaììúô).\n"
				"    GetModeID: îïíâïaëëa, îíéaæúáaýùaþ ïçéáäðñäï üéïaììúô ïäåçëíá ç îäöañaýùaþ "
				"ãäðþñçöìíä öçðêí, ðííñáäñðñáòýùää áúàïaììíëò ïäåçëò.\n"
				"    Kill: îïíâïaëëa, éíñíïaþ ëíåäñ îïäïáañû çðîíêìäìçä ãïòâçô îïíâïaëë, îíðêaá "
				"çë ðçâìaê íðñaìíáa (îïçëäïìí ñí åä, öñí ç  Break.)\n"
				"    MakeLink: æaëäìa ðñaìãaïñìíè éíëaìãú, îíããäïåçáaýùaþ \"ðêaàúä\" "
				"ðáþæç.\n"
				"    DeleteLink: A simple Delete-clone that also deletes soft links "
				"without a target.\n"
				"    UnpackILBM: ïaðîaéíáúáaäñ \"ñäêí\" IFF ILBM óaèêíá "
				"(BODY chunk).\n"
				"    Àíêää îíãïíàìòý çìóíïëaõçý ðë. á ãíéòëäìñaõçç é îïíâïaëëä.\n"
			)
		)

		(set #where-visage "Òéaåçñä ëaïøïòñ ãêþ çìðñaêþõçç Visage")

		(set #where-visage-guide "Éòãa éíîçïíáañû óaèê ãíéòëäìñaõçç Visage.guide?")

		(set #copy-guide-icon "Ìaãí êç éíîçïíáañû çéíìéò ãêþ Visage.guide?")

		(set #convert-guide "Îïäíàïaæòý Visage.guide...")

		(set #which-language "Éaéçä þæúéç ìaãí çìðñaêçïíáañû?")

		(set #which-language-help
			(cat
				"    Aëçâa ëíåäñ ïaàíñañû ìa ëìíâçô þæúéaô. Äðêç Áú ôíñçñä, öñíàú "
				"Visage çðîíêûæíáaê ðñaìãaïñìúè þæúé Áaøäè ðçðñäëú, ñí ìäíàôíãçëí "
				"ðéíîçïíáañû ðííñáäñðñáòýùçä éañaêíâç ìa Áaø å½ðñéçè ãçðé - îííãìíëò "
				"ãêþ éaåãíâí çæ çðîíêûæòäëúô þæúéíá.\n"
				"    Öñíàú òëäìûøçñû íàÿ½ë, æaìçëaäëúè þæúéíáúëç éañaêíâaëç, "
				"áú ëíåäñä ìä áúàçïañû éañaêíâç ãêþ ñäô þæúéíá, éíñíïúä Áaë á îïçìõçîä "
				"ìä îíñïäàòýñðþ.\n"
				"    Îïíðñí îíðñaáûñä âaêíöéç ìaîïíñçá ñïäàòäëúô Áaë þæúéíá ç áð½.\n "
			)
		)

		(set #where-tools "Éòãa çìðñaêçïíáañû ãíîíêìçñäêûìúä îïíâïaëëú?")

		(set #where-tools-help
			(cat
				"    Òéaåçñä ëaïøïòñ éíîçïíáaìçþ îïíâïaëë GetModeID, Kill, MakeLink, "
				"DeleteLink ç UnpackILBM. Àòãòñ ðéíîçïíáaìú ñíêûéí áúàïaììúä Áaëç "
				"îïíâïaëëú. Îíðéíêûéò æaîòðéañû áðä üñç îïíâïaëëú áíæëíåìí ñíêûéí çæ "
				"Shell, ñí îïäãîíêaâaäñðþ ðéíîçïíáañû çô á C:, âãä, éaé îïaáçêí, "
				"ìaôíãþñðþ îíãíàìúä îïíâïaëëú.\n"
				"    Á êýàíë ðêòöaä åäêañäêûìí, öñíàú üñç îïíâïaëëú ìaôíãçêçðû îí íãìíëò "
				"çæ ãíðñòîìúô ëaïøïòñíá Áaøäè ðçðñäëú.\n"
			)
		)

		(set #copy "Éíîçïòý %s á %s...")

		(set #program-update "Éaé Áú ôíñçñä íàìíáçñû çìðñïòëäìñaïçè çéíìéç?")

		(set #update-none "Ìä ôíöò")

		(set #update-all "Ãíàaáçñû áð½")

		(set #update-since "Ãíàaáçñû, ìaöçìaþ ð %s")

		(set #program-update-help
			(cat
				"    Îíðéíêûéò ëú ðäèöað íàìíáêþäë àíêää ðñaïòý áäïðçý Visage, ñí "
				"ðñaïaþ çéíìéa ìä îäïäîçðúáaäñðþ æaìíáí. Üñí ðãäêaìí ãêþ ñíâí, öñíàú "
				"ðíôïaìçñû ñä çæëäìäìçþ, éíñíïúä Áú ëíâêç îïíçæáäðñç ïaìää. Íãìaéí, "
				"ìçöñí ìä ëäøaäñ ìaë ãíàaáçñû ìíáúä îaïaëäñïú. Æãäðû áú ëíåäñä "
				"ïäøçñû, ôíñçñä êç Áú:\n"
				"    Ìçöäâí ìä íàìíáêþñû.\n"
				"    Ãíàaáçñû ìíáúä îaïaëäñïú é òåä ðòùäðñáòýùçë. "
				"Êýàúä áíæëíåìí òãaê½ììúä Áaëç ïaìää îaïaëäñïú àòãòñ ðìíáa ãíàaáêäìú, "
				"ïaáìí éaé ç ìíáúä îaïaëäñïú.\n "
				"    Ãíàaáçñû îíðêä 39.x: ãíàaáçñû ìíáúä îaïaëäñïú ñíêûéí îíðêä üñíè áäïðçç ÃÍÐ. "
				"Ðòùäðñáòýùçä îaïaëäñïú íðñaìòñðþ ìäçæëäììúëç.\n"
			)
		)

		; JPEG codec

		(set #codec-message
			(cat
				"\n\n\nTower JPEG Codec Class\n\nCopyright © 1994 Christoph Feck, TowerSystems\n"
				"Áðä îïaáa æaùçùäìú.\n\n\n\n"
				"Îíãïíàìíðñç ðë. á ãíéòëäìñaõçç."
			)
		)

		(set #jpeg-tmp-prompt
			"Áúàäïçñä éañaêíâ ãêþ áïäëäììúô óaèêíá (ñíêûéí ìä á RAM:)"
		)

		(set #temp-file
			(cat
				"    Ãêþ ãäéíãçïíáaìçþ ìäéíñíïúô JPEG-éaïñçìíé, éêaðð Codec ñïäàòäñ "
				"æìaöçñäêûìúô íàÿ½ëíá îaëþñç.\n"
				"Äðêç íîäïañçáìíè îaëþñç ìäãíðñañíöìí, ñí Codec ðíæãaðñ áïäëäììúè óaèê ìa "
				"Áaøäë å½ðñéíë ãçðéä. Îaïñçõçþ, ìa éíñíïíè üñíñ óaèê àòãäñ ðíæãaì, ãíêåìa "
				"çëäñû ðáíàíãìúè íàÿ½ë ìä ëäìää 4-ô ëäâaàaèñ.\n"
				"    Á íàùäë ðêòöaä, üñíñ óaèê ñïäàòäñðþ ñíêûéí ãêþ îïçáäãäìçþ JPEG-éaïñçìéç "
				"é 256-ñç õáäñaë.\n\n"
				@askdir-help
			)
		)

		(set #jpeg-startup-prompt
			"Ìaãí éíä-öñí ãíàaáçñû á óaèê S:user-startup."
		)

		(set #make-assign
			(cat
				"    Êíâçöäðéíä çëþ \"JPEGTMP:\" çðîíêûæòäñðþ ãêþ ððúêéç ìa áïäëäììúè "
				"éañaêíâ ãêþ JPEG-éaïñçìíé.\n"
				"    Öñíàú üñí çëþ àúêí ãíðñòîìí îíðêä éaåãíâí (ïä)ðñaïña éíëîûýñäïa, "
				"éíëaìãa \"Assign\" ãíêåìa àúñû ãíàaáêäìa á óaèê \"user-startup\".\n\n"
				@startup-help
			)
		)

		(set #jpeg-copy "Éíîçïòý %s...")
	)
)


;**************************************************************************
;
; Serbian (?) strings
;

; .ct
(if (= @language "srpski")
	(
		(set #default-lang #serbian-lang)
	)
)


;**************************************************************************
;
; Finnish strings
;

; .ct
(if (= @language "suomi")
	(
		(set #default-lang #finnish-lang)
	)
)


;**************************************************************************
;
; Swedish strings
;

(if (= @language "svenska")
	(
		(set #default-lang #swedish-lang)

		(set #bad-kick
			"Du måste ha AmigaOS version 3.0 eller högre för att kunna använda Visage."
		)

		(set #welcome
			(cat
				"\n\n\nVälkommen till Installeraren.\n\n"
				"Det här programmet låter dig installera Visage i din Amiga.\n\n\n"
				"Visage © 1995  Magnus Holmgren."
			)
		)

		(set #install-parts "Välj de delar du vill installera:")

		(set #item-visage "Visage")

		(set #item-visage-guide "Visage.guide")

		(set #item-locale "Översättningar")

		(set #item-codec "JPEG codec")

		(set #install-parts-help
			(cat
				"  Här väljer du de olika delar av Visage som du vill installera. "
				"Efter det anger du detaljer om installationen (såsom var de olika "
				"filerna ska installeras). Du kan välja mellan följande delar:\n"
				"  Visage: Själva bildvisaren.\n"
				"  Visage.guide: Manualen, i AmigaGuide®-format. Om du installerar "
				"den med Installeraren, så kommer texten att formateras om efter "
				"fönstrets aktuella storlek. Om du installerar den manuellt, så "
				"är texten fixerad vid 76 kolumner.\n"
				"  Översättningar: Om du installerar en översättning, så kan "
				"Visage använda det språket.\n"
				"  JPEG codec: \"The Tower JPEG Codec Class\". Visage behöver "
				"den här för att kunna visa JPEG-bilder.\n"
				"  GetModeID: Ett program som visar en skärmlägesväljare, och "
				"sedan skriver ut ett decimalt tal som motsvarar det valda "
				"skärmläget.\n"
				"  Kill: Ett program som kan stoppa andra program (genom att "
				"skicka \"break\"-signaler). Liknar Break.\n"
				"  MakeLink: En erättning för MakeLink, som stödjer så kallade "
				"mjuka länkar.\n"
				"  DeleteLink: En enkel Delete-variant, som också kan radera "
				"mjuka länkar där målfilen saknas.\n"
				"  UnpackILBM: Ett program som packar upp bilddatan i en IFF ILBM "
				"bild (BODY \"chunken\").\n"
				"    För mer information om de här sakerna, se manualen.\n"
			)
		)

		(set #where-visage "Var vill du installera Visage?\nEn låda kommer INTE att skapas!")

		(set #where-visage-guide "Var vill du installera Visage.guide?")

		(set #copy-guide-icon "Ska jag kopiera ikonen för Visage.guide?")

		(set #convert-guide "Konverterar Visage.guide...")

		(set #which-language "Vilka språk ska installeras?")

		(set #which-language-help
			(cat
				"  Amigan kan arbeta med flera olika språk. Om du vill att "
				"Visage ska använda samma språk som Amiga Workbench så "
				"måste en så kallad katalogfil kopieras till din systemdisk "
				"för varje språk.\n"
				"  För att minimera diskutrymmet för språkfiler kan du välja "
				"att bara installera filerna för vissa språk.\n"
				"  Markera bara rutorna för de språk du önskar installera i "
				"din dator.\n"
			)
		)

		(set #where-language
			(cat
				"Var vill du installera katalogfilerna?\n\n"
				"Du kan antingen installera dem i samma låda som programmet "
				"(välj \"Program\"), eller i den 'globala' enheten "
				"\"Locale:\" (välj \"Locale:\")."
			)
		)

		(set #lang-progdir "Program")

		(set #lang-locale  "Locale:")

		(set #where-language-help
			(cat
				"  Om du installerar katalogfilerna i samma låda som "
				"Visage (eller snarare i underlådor i den lådan), så "
				"kommer du att behöva flytta de här filerna, om du "
				"flyttar Visage till någon annan läda. Om du installerar "
				"katalogfilerna i \"Locale:\" så behöver du inte bekymra "
				"dig om dem ifall du flyttar Visage. Å andra sidan, alla "
				"Visage-relaterade filler kommer inte att finnas i samma "
				"låda."
			)
		)

		(set #builtin-lang "(inbyggt)")

		(set #where-tools "Var vill du installera de extra programmen?")

		(set #where-tools-help
			(cat
				"  Här anger du var programmen GetModeID, Kill, MakeLink "
				"DeleteLink och UnpackILBM ska installeras någonstans. Bara "
				"de program som du valde tidigare kommer att kopieras. "
				"Eftersom de här programmen bara kan användas från ett "
				"skal, så är den förvalda destinationen C:, eftersom "
				"systemets \"skalprogram\" finns där. Det rekommenderas "
				"att du installerar dessa program någonstans i sökvägen "
				"för kommandon.\n"
			)
		)

		(set #copy "Kopierar %s till %s...")

		(set #program-update "Hur vill du uppdatera verktygstyperna i ikonen?")

		(set #update-none "Uppdatera inte")

		(set #update-all "Lägg till alla")

		(set #update-since "Lägg till nya sedan %s")

		(set #program-update-help
			(cat
				"  Eftersom den här installationen uppdaterar en gammal version "
				"av Visage, så kommer inte ikonen att kopieras. Detta för att "
				"bibehålla eventuella ändringar som du kan ha gjort. Men nya "
				"verktygstyper kan ha tillkommit. Här kan du avgöra vad du "
				"vill göra:\n"
				"  Uppdatera inte: Hoppa över detta.\n"
				"  Lägg till alla: Lägg till alla verktygstyper. Existerande "
				"verktygstyper kommer inte att ändras.\n"
				"  Lägg till nya sedan 39.x: Lägg bara till de nya "
				"verktytstyperna. Eventuella existerande verktygstyper "
				"kommer inte att ändras.\n"
			)
		)

		; JPEG codec

		(set #temp-file
			(cat
				"  För att packa upp vissa JPEG-bilder, så behöver Codec:en "
				"mycket minne.\n"
				"  Om det inte finns nog med plats i huvudminnet, så kommer "
				"Codec:en att skapa en temporärfil på din hårddisk. Volymen "
				"på vilken den här filen skapas bör ha tillräcklikt med fritt "
				"utrymme (ungefär 4 MB).\n"
				"  En temporärfil behövs normalt sett bara om du vill "
				"kvantisera JPEG-bilder till 256 färger.\n\n"
				@askdir-help
			)
		)

		(set #make-assign
			(cat
				"  Den logiska tilldelningen \"JPEGTMP:\" används för att "
				"referera till lådan för temporära filer.\n"
				"  För att göra den här tilldelningen tillgänglig vid varje "
				"systemstart så behöver ett \"Assign\"-kommando läggas till "
				"i din \"user-startup\"-fil.\n\n"
				@startup-help
			)
		)

		(set #codec-message
			(cat
				"\n\n\nTower JPEG Codec Class\n\n"
				"Upphovsrätt © 1994 Christoph Feck, TowerSystems\n"
				"Alla rättigheter reserverade.\n\n\n\n"
				"Var god läs dokumentationen för detaljer."
			)
		)

		(set #jpeg-tmp-prompt
			"Välj en låda för temporära filer, inte i RAM:"
		)

		(set #jpeg-startup-prompt
			"En tilldelning måste läggas till i din user-startup."
		)

		(set #jpeg-copy "Kopierar %s...")
	)
)

;**************************************************************************
;
; The actual installaion script
;

; Check Kickstart version. Exit if not at least 3.0
(if (< (/ (getversion) 65536) 39)
        (abort #bad-kick)
)

; Since files probably are scatter installed, don't mention any specific location.
(set @default-dest "")

; Version of old program. This means no old program.
(set #visagever 0)
(set #visagerev 0)

; Request proportinal fonts, if supported. This string is
; prepended to the first askoptions choice.
(if (>= @installer-version 2752518)     ; 42 * 65536 + 6
	; At least version 42.6
	(set #propfont "")
	; Pre V42
	(set #propfont "")
)

; Greetings Mr. Falken...
(message #welcome)

(welcome)

; Ask the user what to install
(set #install-files
	(askoptions
		(prompt	#install-parts)
		(help	#install-parts-help "\n" @askoptions-help)
		(choices
			(cat #propfont #item-visage)
			#item-visage-guide
			#item-locale
			#item-codec
			#item-getmodeid
			#item-kill
			#item-makelink
			#item-deletelink
			#item-unpackilbm
		)
		(default (if (= @user-level 2) 511 15))
	)
)

; Ask the user for the location of all parts

; Location for Visage
(if (BITAND #install-files 1)
	(
		(set #visage-dest
			(askdir
				(prompt  #where-visage)
				(help    @askdir-help)
				(default "Sys:Utilities")
			)
		)

		; Get the version of previously installed Visage
		(if (= (exists (tackon #visage-dest "Visage")) 1)
			(
				(set #vernum (getversion (tackon #visage-dest "Visage")))
				(set #visagever (/ #vernum 65536))
				(set #visagerev (- #vernum (* #visagever 65536)))

				; Just in case the above failed...
				(if (<= #visagever 38)
					(
						(set #visagever 39)
						(set #visagerev 0)
					)
				)
			)
		)

		(set #update-action 0)

		(if (AND #visagever (= (exists (tackon #visage-dest "Visage.info")) 1))
			(
				(set #defaction 0)

				(if (= #visagerev 0)
					(set #defaction 2)
				)

				(if (= #visagerev 1)
					(set #defaction 3)
				)

				(if (= #visagerev 2)
					(set #defaction 4)
				)

				(if (= #visagerev 5)
					(set #defaction 5)
				)

				(if (= #visagerev 10)
					(set #defaction 6)
				)

				(set #update-action
					(askchoice
						(prompt		#program-update)
						(choices	(cat #propfont #update-none)
								#update-all
								(#update-since "39.0")
								(#update-since "39.1")
								(#update-since "39.2")
								(#update-since "39.5")
								(#update-since "39.10")
						)
						(default	#defaction)
						(help		#program-update-help "\n" @askchoice-help)
					)
				)

				(set #tt39-1  "DITHER COMPACT TIME")
				(set #tt39-2  "COMMAND CYCLE NOCLICK NORMALNAMES RTG SORT TEST VCENTER")
				(set #tt39-3  "INFO SHOWINFO")
				(set #tt39-6  "NOICON NOFOREIGN")
				(set #tt39-11 "BORDERBLANK NOFILECHECK")

				(set #icon-dest (tackon #visage-dest "Visage"))
				(set #tooltype-pattern
					(select #update-action
						""
						"#?"
						("%s %s %s %s %s" #tt39-11 #tt39-6 #tt39-3 #tt39-2 #tt39-1)
						("%s %s %s %s"    #tt39-11 #tt39-6 #tt39-3 #tt39-2)
						("%s %s %s"       #tt39-11 #tt39-6 #tt39-3)
						("%s %s"          #tt39-11 #tt39-6)
						("%s"             #tt39-11)
					)
				)
			)
		)
	)
)

; Location for Visage.guide
(if (BITAND #install-files 2)
	(
		(set #guide-dest visage-dest)

		(if (exists "Help:")
			(set #guide-dest "Help:")
		)

		(set #guide-dest
			(askdir
				(prompt  #where-visage-guide)
				(help    @askdir-help)
				(default #guide-dest)
			)
		)

		(set #dest-guide-name (tackon #guide-dest "Visage.guide.info"))

		(set #guide-icon
			(if (AND (= @user-level 2 ) (= (exists #dest-guide-name) 0))
				(askbool
					(prompt #copy-guide-icon)
					(help	" ")
				)
				1	; Default is to copy the icon
			)
		)
	)
)

(set #languages 0)

; .ct
; Which languages that should be installed.
(if (BITAND #install-files 4)
	(set #lang
		(askoptions
			(prompt	#which-language)
			(help	#which-language-help "\n" @askoptions-help)
			(choices
				(cat #propfont "Deutsch")
				(cat "English  " #builtin-lang)
				"Español"
				"Français"
				"Italiano"
				"Nederlands"
				"Norsk"
				"Russian"
				"Srpski"
				"Suomi"
				"Svenska"
			)
			(default #default-lang)
		)
	)
)

; Default to install catalog files in the same drawer as Visage.
(set #catalog-dest (tackon #visage-dest "Catalogs"))

; Where should the catalogs be installed? Only do this if we have
; an expert user, and any non-english language was selected.
(if (AND (BITAND #install-files 1) (<> #lang 0) (<> #lang #english-lang) (= @user-level 2))
	(
		(set #choice
			(askbool
				(prompt  #where-language)
				(help    #where-language-help "\n" @askbool-help)
				(default 1)
				(choices #lang-progdir #lang-locale)
			)
		)

		(if (NOT #choice)
			(set #catalog-dest "Locale:Catalogs")
		)
	)
)

; Ask for location for extra tools
(if (BITAND #install-files 496)	; 16 + 32 + 64 + 128 + 256
	(set #tool-dest
		(askdir
			(prompt	#where-tools)
			(help	#where-tools-help "\n" @askdir-help)
			(default "C:")
		)
	)
)

; And now do the actual installation

(complete 0)

(if (BITAND #install-files 1)
	(
		(copylib
			(prompt	(#copy "Visage" visage-dest))
			(source	"Visage")
			(dest	#visage-dest)
		)

		(if (= (exists (tackon #visage-dest "Visage.info")) 0)
			(copyfiles
				(source	"Visage.info")
				(dest	#visage-dest)
			)
			(if (> #update-action 0)
				(run ("C/UpdateTT Visage %s %s" #icon-dest #tooltype-pattern))
			)
		)
	)
)

(complete 20)

(if (BITAND #install-files 2)
	(
		(working #convert-guide)

		(run "C/FixAG Visage.guide T:Visage.Guide")

		(copylib
			(prompt (#copy "Visage.guide" guide-dest))
			(source "T:Visage.guide")
			(dest   #guide-dest)
		)

		(delete "T:Visage.guide" (safe))

		(if #guide-icon
			(copyfiles
				(source "Visage.guide.info")
				(dest   #guide-dest)
			)
		)
	)
)

(complete 40)

; .ct
(if (BITAND #install-files 4)
	(
		(if (= (exists #catalog-dest) 0)
			(makedir #catalog-dest)
		)

		(set #n 0)

		(while
			(set #language
				(select #n
					"Deutsch"
					"English"
					"Español"
					"Français"
					"Italiano"
					"Nederlands"
					"Norsk"
					"Russian"
					"Srpski"
					"Suomi"
					"Svenska"
					""
				)
			)

			(
				(if (AND (IN #lang #n) (<> #language "English"))
					(
						(set #catalog
							(tackon "Catalogs"
								(tackon #language "visage.catalog")
							)
						)

						(set #destination (tackon #catalog-dest #language))

						(copylib
							(prompt (#copy #catalog #destination))
							(source #catalog)
							(dest   #destination)
						)
					)
				)

				(set #n (+ #n 1))
			)
		)
	)
)

(complete 45)

(if (BITAND #install-files 16)
	(copylib
		(prompt (#copy "GetModeID" #tool-dest))
		(source "C/GetModeID")
		(dest   #tool-dest)
	)
)

(if (BITAND #install-files 32)
	(copylib
		(prompt (#copy "Kill" #tool-dest))
		(source "C/Kill")
		(dest   #tool-dest)
	)
)

(if (BITAND #install-files 64)
	(copylib
		(prompt (#copy "MakeLink" #tool-dest))
		(source "C/MakeLink")
		(dest   #tool-dest)
	)
)

(if (BITAND #install-files 128)
	(copylib
		(prompt (#copy "DeleteLink" #tool-dest))
		(source "C/DeleteLink")
		(dest   #tool-dest)
	)
)

(if (BITAND #install-files 256)
	(copylib
		(prompt (#copy "UnpackILBM" #tool-dest))
		(source "C/UnpackILBM")
		(dest   #tool-dest)
	)
)

(complete 50)

; JPEG codec installation

(if (BITAND #install-files 8)
	(
		;****************************************************************************
		;
		; Setup
		;

		(set #libs-dest "LIBS:")
		(set #class-dest "SYS:Classes")

		(if (not (exists #class-dest))
			(set #class-dest "LIBS:")
		)

		;****************************************************************************
		;
		; Welcome
		;

		(message #codec-message)

		;****************************************************************************
		;
		; JPEGTMP: assignment
		;

		(set #has-temp 0)

		(if (exists "JPEGTMP:" (noreq))
			(
				(set #has-temp 1)
				(if (= "RAM" (getdevice "JPEGTMP:"))
					(set #has-temp 0)
				)
			)
		)

		(if (= #has-temp 0)
			(
				(set #jpeg-tmp (askdir (help #temp-file) (prompt #jpeg-tmp-prompt) (default "SYS:")))
				(startup "JPEG Codec"
					(help #make-assign)
					(prompt #jpeg-startup-prompt)
					(command "Assign JPEGTMP: \"" #jpeg-tmp "\"")
				)
				(makeassign "JPEGTMP" #jpeg-tmp)
			)
		)

		(complete 60)

		;****************************************************************************
		;
		; Install libraries and classes
		;

		(copylib
			(help @copylib-help)
			(prompt (#jpeg-copy "tower.library"))
			(source "Libs/tower.library")
			(dest #libs-dest)
			(confirm)
		)

		(complete 70)

		(copylib
			(help @copylib-help)
			(prompt (#jpeg-copy "codec.class"))
			(source "Classes/codec.class")
			(dest #class-dest)
			(confirm)
		)

		(complete 80)

		(copylib
			(help @copylib-help)
			(prompt (#jpeg-copy "picture.codec"))
			(source "Classes/Codecs/picture.codec")
			(dest (tackon #class-dest "Codecs"))
			(confirm)
		)

		(complete 90)

		(copylib
			(help @copylib-help)
			(prompt (#jpeg-copy "jpeg.codec"))
			(source "Classes/Codecs/jpeg.codec")
			(dest (tackon #class-dest "Codecs"))
			(confirm)
		)

		;****************************************************************************
		;
		; Exit
		;

		(run "Avail >Nil: FLUSH")
	)
)

(complete 100)

(exit)