; SysPic Installer Script
; $VER: Install SysPic 4.0 (23.09.96)
; written by Grzegorz Calkowski

; =======================================================================

; Strings

(set #kick39 "SysPic requires at least Kickstart 3.0 (v39) !")
(set #syspicdir "Select drawer for SysPic executable")
(set #closepicdir "Select drawer for ClosePic")
(set #cmdsdir "Select drawer for additional commands")
(set #selcmds "Select what commands to install")
(set #ptreplay "Installing ptreplay.library")
(set #messy "\nSysPic has been installed.\n\nNow you have to edit startup-sequence by hand -\ninsert 'SysPic <filename> <options>' command\nright after 'SetPatch' command.\n\nConsult the documentation for details.")

; =======================================================================

(if (< (/ (getversion) 65536) 39)
	(abort #kick39)
)

(set cpu (database "cpu"))
(set prgver "SysPic")
(set picsdir "")

; Determine SysPic version

(if (NOT (= cpu "68000"))
	(set prgver "SysPic.020")
)

(if (exists 'C2:' (noreq))
	(set destdir "C2:")
	(set destdir "C:")
)

(copyfiles
	(source (cat "C/" prgver))
	(dest (set destdir (askdir
		(help @askdir-help)
		(default destdir)
		(prompt #syspicdir)
	)))
	(newname "SysPic")
	(help @copyfiles-help)
)

(set @default-dest destdir)

(copyfiles
	(source "WBStartup/ClosePic")
	(dest (askdir
		(prompt #closepicdir)
		(help @askdir-help)
		(default 'SYS:WBStartup')
	))
	(infos)
	(help @copyfiles-help)
)

(copyfiles
 (prompt #selcmds)
	(source "C/")
 (pattern "~S#?")
	(dest (set cmdsdir (askdir
		(help @askdir-help)
		(default destdir)
		(prompt #cmdsdir)
	)))
	(confirm)
	(help @copyfiles-help)
)

(copylib
	(prompt #ptreplay)
	(source "Libs/ptreplay.library")
	(dest "LIBS:")
	(help @copylib-help)
	(confirm)
)

(message #messy)