;================================= FRANCAIS ==================================

(set #bad-kick "Le Kickstart 3.0 (V39) est le minimum requis pour faire fonctionner ShutAll")

(set #copy-main "Copie de ShutAll en cours...")
(set #copy-samples "Copies des Sons en cours...")
(set #copy-prefs "Copie du programme de préférences en cours...")
(set #copy-doc "Copie de la Documentation en cours...")
(set #copy-dock "Copie du Dock en cours...")
(set #copy-lib "Copie de l'iffparse.library vers Libs: en cours...")

(set #drawer-main "Creation du répertoire ShutAll...")
(set #drawer-samples "Création du répertoire Samples...")


(set #inst-doc "\n\nVoulez-vous installer la Documentation AmigaGuide en français ?")
(set #inst-samples "\n\nVoulez-vous installer le répertoire des Sons ?\n(Oui Oui Oui !!!)")
(set #inst-dock "\n\nVoulez-vous installer le Dock pour ToolManager ?\n(très pratique)")

(set #where-main "Où voulez-vous installer le répertoire ShutAll ?")
(set #where-main-help
	(cat
		"Voici le chemin de destination pour ShutAll\n. Un répertoire ShutAll va être créé ici."
	)
)
(set #where-doc "Où voulez-vous installer la Documentation ?")
(set #where-samples "Où voulez-vous installer le répertoire des Sons ?\nUn répertoire appelé Samples va être créé ici.")
(set #where-dock "Où voulez-vous installer le Dock pour ToolManager ?")
(set #where-prefs "Où voulez-vous installer le Programme de Préférences ?")


(set #install-exit "Merci d'avoir installer ShutAll ...")
(set #install-start
	(cat
		"\n\n"
		"~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~\n\n"
		"Bienvenue dans 'installer de ShutAll !\n\n"
		"créé par Stéphane NICOLE\n\n"
		"Octobre 1996\n\n"
		"~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~\n\n"
		"Dorénavant éteindre votre Amiga sera un plaisir !!!"
	)
)
(set doc-file "ShutAll_fra.guide")

;============================== PROGRAM-START================================

(set @default-dest "SYS:")

; Check Kickstart (>= v3.0) Version.

(if (< (/ (getversion) 65536) 39)
	(abort #bad-kick)
)

(message #install-start)


(welcome)

;-------------------------------
; Ask for Main prog Installation
;-------------------------------

(set startup-files 0)

(set main-dest
	(askdir
	(help "")
	(prompt	#where-main)
	(default @default-dest)
	)
)

;-------------------
; New default drawer
;-------------------

(set @default-dest
  (tackon main-dest "ShutAll")
)

;----------------------------------
; Create Drawer & Copy Main Program
;----------------------------------

(complete 0)

(makedir @default-dest
	(prompt #drawer-main)
	(help "")
	(infos)
)


(copyfiles
	(prompt #copy-main)
	(source "ShutAll")
	(dest @default-dest)
	(files)
	(infos)
)

;----------------------
; Copy Preferences Prog
;----------------------

(complete 10)

(set prefs-dest
	(askdir
	(help "")
	(prompt	#where-prefs)
	(default @default-dest)
	)
)

(copyfiles
	(prompt #copy-prefs)
	(source "SA_Prefs")
	(dest prefs-dest)
	(files)
	(infos)
)


;----------------------
; Ask for documentation
;----------------------

(complete 25)


(set copy-doc
	(askbool
		(prompt #inst-doc)
		(help "")
	)
)

;-------------------
; Copy documentation
;-------------------

(if copy-doc
	(set doc-dest
		(askdir
		(help "")
		(prompt	#where-doc)
		(default @default-dest)
		)
	)
)

(if copy-doc
	(copyfiles
		(prompt #copy-doc)
		(source doc-file)
		(dest doc-dest)
		(files)
		(infos)
	)
)

;----------------------
; Ask for Dock Icon
;----------------------

(complete 50)


(set copy-dock
	(askbool
		(prompt #inst-dock)
		(help "")
	)
)

;-------------------
; Copy DockIcon
;-------------------

(if copy-dock
	(set dock-dest
		(askdir
		(help "")
		(prompt	#where-dock)
		(default @default-dest)
		)
	)
)

(if copy-dock
	(copyfiles
		(prompt #copy-dock)
		(source "ShutAll-Dock.info")
		(dest dock-dest)
		(files)
		(infos)
	)
)




;----------------------
; Ask for samples
;----------------------

(complete 75)

(set copy-samples
	(askbool
		(prompt #inst-samples)
		(help "")
	)
)


;-------------------
; Copy samples
;-------------------

(set @default-dest
 	(tackon @default-dest "Samples")
)


(if copy-samples
	(copyfiles
		(prompt #copy-samples)
		(source "Samples/")
		(dest @default-dest)
		(confirm 2)
		(all)
		(help "")
		(infos)
	)
)




(complete 100)

(EXIT #install-exit)