(
    (set #dest
	(askdir
	    (prompt "Select the directory to install TragicWB to:")
	    (help @askdir-help)
	    (default "C:")
	)
    )

    (set @default-dest #dest)

    (copyfiles (source "TragicWB") (dest #dest) (prompt "") (help ""))

    (complete 20)

    (startup @app-name
	(command (tackon #dest "TragicWB"))
	(prompt "Do you want TragicWB to start when you boot your Amiga?")
	(help "If you answer Yes, TragicWB will be added to your"
	      "user-startup file, so it will start automatically"
	      "when you switch on or reboot your Amiga. If you"
	      "answer No, you will have to start TragicWB"
	      "from a CLI, which isn't very convenient and"
	      "may not work unless you reset the Workbench screen.")
    )

    (complete 40)

    (set #installpal
	(or
	    (= @user-level 0)
	    (askbool
		(prompt "Do you want to use the Magic Workbench palette?")
		(help "If you answer Yes, your palette preferences will"
		      "be set to the Magic Workbench  colour scheme. If you answer"
		      "No, then your palette will not be changed, and"
		      "old-style Magic Workbench icons will still have the wrong"
		      "colours.")
	    )
	)
    )

    (set #startnow
	(or
	    (= @user-level 0)
	    (askbool
		(prompt "Do you want to start TragicWB now?")
		(help "If you answer Yes, TragicWB will be started as"
		      "soon as it has been installed. If you answer"
		      "No, it will not start until you reboot or run"
		      "it from a CLI.")
	    )
	)
    )

; Don't blame me for this. Tf the user chooses to start TragicWB
; now, I must do (run "TragicWB" ...). But I must also copy
; MWB-palette.pre to env:sys/, if the user chose to do that as
; well. So I have to ask in advance and then perform actions
; based on two questions without re-prompting - which would be stupid.
; If anyone can tell me a better way to do this, I'll use it in future.
    (set @user-level 0)

    (if #installpal
	(copyfiles (source "MWB-palette.pre") (dest "envarc:sys") (newname "palette.prefs") (prompt "") (help ""))

	(complete 60)

	(if #startnow
	    (copyfiles (source "MWB-palette.pre") (dest "env:sys") (newname "palette.prefs") (prompt "") (help ""))
	)
    )

    (complete 80)

    (if #startnow
	(run (tackon #dest "TragicWB") (prompt "") (help ""))
    )

    (complete 100)
)