;Double Buffering
;----------------
;This just shows how to double buffer the screen.  You can also try out
;triple buffering just by changing the DBLBUFFER flag to TPLBUFFER in the
;ScreenStruct.
;
;Notice that this thing does in fact fully multi-task (no forbid/permit)!
;Instead we set our task priority to be a little higher than any other tasks
;-- if we didn't do this sometimes our frames could be stalled (try removing
;the SetUserPri and watch the demo again).

	opt	o+

	INCLUDE	"exec/exec_lib.i"
	INCLUDE	"games/games_lib.i"
	INCLUDE	"games/games.i
CALL	MACRO
	jsr	_LVO\1(a6)
	ENDM

	SECTION	"DoubleBuffer",CODE

;===========================================================================;
;                             INITIALISE DEMO
;===========================================================================;

Start:	MOVEM.L	A0-A6/D1-D7,-(SP)
	move.l	($4).w,a6
	lea	GMS_Name(pc),a1
	moveq	#$00,d0
	CALL	OpenLibrary
	move.l	d0,GMS_Base
	beq.s	.Error_GMS

	move.l	GMS_Base(pc),a6
	sub.l	a0,a0
	CALL	SetUserPrefs

	lea	Screen(pc),a0		;Add screen for use.
	CALL	Add_Screen
	tst.l	d0
	bne.s	.Error_Screen

	lea	Picture(pc),a1		;Load background picture.
	move.l	GS_MemPtr1(a0),PIC_Data(a1)
	CALL	LoadPic
	tst.w	d0
	bne.s	.Error_Picture

	move.l	PIC_Palette(a1),GS_Palette(a0)
	CALL	UpdatePalette

	CALL	Show_Screen

	bsr.s	Main

.ReturnToDOS
	move.l	GMS_Base(pc),a6
	lea	Picture(pc),a1
	CALL	FreePic
.Error_Picture
	lea	Screen(pc),a0
	CALL	Delete_Screen		;Give back screen memory etc.
.Error_Screen
	move.l	GMS_Base(pc),a1
	move.l	($4).w,a6
	CALL	CloseLibrary
.Error_GMS
	MOVEM.L	(SP)+,A0-A6/D1-D7
	moveq	#$00,d0
	rts

;===========================================================================;
;                                MAIN LOOP
;===========================================================================;

Main:	CALL	Wait_OSVBL		;Nice VBL wait for multi-tasking.
	CALL	SwapBuffers
	moveq	#JPORT1,d0
	moveq	#JT_ZBXY,d1
	CALL	Read_JoyPort
	btst	#MB_LMB,d0
	beq.s	Main
	rts

;===========================================================================;
;                                  DATA
;===========================================================================;

GMS_Name:
	dc.b	"games.library",0
	even
GMS_Base:
	dc.l	0

AMT_PLANES =	5

Screen:	dc.l	"GSV1",0		;Structure Version.
	dc.l	0,0,0			;Screen Memory 1/2/3.
	dc.l	0			;Screen link.
	dc.l	0			;Address of screen palette
	dc.l	0			;Address of rasterlist.
	dc.l	0			;Amt of colours in palette.
	dc.w	320,256			;Screen Width and Height.
	dc.w	320/8,256		;Picture Width/8 and Height.
	dc.w	AMT_PLANES		;Amt of planes
	dc.w	0,0			;X/Y screen offset
	dc.w	0,0			;X/Y picture offset
	dc.l	DBLBUFFER		;Special attributes.
	dc.w	LORES|COL12BIT		;Screen mode.
	dc.b	PLANAR			;Screen type
	dc.b	0			;Reserved.
	even

Picture	dc.l	"PCV1",0		;Version header.
	dc.l	0			;Source data.
	dc.w	320/8,256		;Width, Height.
	dc.w	AMT_PLANES		;Amount of Planes.
	dc.l	32			;Amount of colours.
	dc.l	0			;Source palette (remap).
	dc.w	LORES|COL12BIT		;Screen mode.
	dc.w	PLANAR			;Screen type.
	dc.l	GETPALETTE		;Parameters.
	dc.l	.File
.File	dc.b	"GAMESLIB:data/IFF.Pic320",0
	even