;AGA White Fade
;--------------
;Fades the screen to white, then down to a palette, and exits with a fade
;to black.
;
;This demo can load and fade any picture that you specify at the end of
;this file.
;
;Press left mouse button to exit.

	opt	o+

	INCLUDE	"exec/exec_lib.i"
	INCLUDE	"games/games_lib.i"
	INCLUDE	"games/games.i"

CALL	MACRO
	jsr	_LVO\1(a6)
	ENDM

	SECTION	"AGAWhiteFade",CODE

;===========================================================================;
;                             INITIALISE DEMO
;===========================================================================;

Start:	MOVEM.L	A0-A6/D1-D7,-(SP)
	move.l	($4).w,a6
	lea	GMS_Name(pc),a1
	moveq	#$00,d0
	CALL	OpenLibrary
	move.l	d0,GMS_Base
	beq.s	.Error_GMS

	move.l	GMS_Base(pc),a6		;Initialise our screen.
	sub.l	a0,a0
	CALL	SetUserPrefs

	lea	Screen(pc),a0
	lea	Picture(pc),a1		;Load the picture.
	CALL	LoadPic
	tst.w	d0
	bne.s	.Error_Picture

	move.l	PIC_Palette(a1),GS_Palette(a0)
	move.l	PIC_AmtColours(a1),GS_AmtColours(a0)
	move.w	PIC_Planes(a1),GS_Planes(a0)
	move.l	PIC_Data(a1),GS_MemPtr1(a0)
	CALL	Add_Screen
	tst.l	d0
	bne.s	.Error_Screen

	CALL	Show_Screen

	bsr.s	Main

.ReturnToDOS
	move.l	GMS_Base(pc),a6
	lea	Picture(pc),a1
	CALL	FreePic
.Error_Picture
	lea	Screen(pc),a0
	CALL	Delete_Screen
.Error_Screen
	move.l	($4).w,a6
	move.l	GMS_Base(pc),a1
	CALL	CloseLibrary
.Error_GMS
	MOVEM.L	(SP)+,A0-A6/D1-D7
	moveq	#$00,d0
	rts

;===========================================================================;
;                                MAIN CODE
;===========================================================================;

Main:	lea	Screen(pc),a0
	moveq	#$00,d0	;d0 = FadeState (reset).
	moveq	#5,d1	;d1 = Speed of fade.
	moveq	#$000000,d2	;d2 = Source colour
	move.l	#$ffffff,d5	;d5 = Destination colour.
	moveq	#00,d3	;d3 = Start colour
	move.l	GS_AmtColours(a0),d4	;d4 = Amount of colours.
.f_in	CALL	Wait_OSVBL
	CALL	ColourMorph	;Do the fade routine.
	tst.w	d0	;Has the fade finished yet?
	bne.s	.f_in	;If not, keep doing it.

	moveq	#2,d1	;d1 = Speed of fade.
	move.l	GS_Palette(a0),a1	;a1 = Palette to fade to.
	move.l	#$ffffff,d2	;d2 = Colour we are fading from.
.f_mid	CALL	Wait_OSVBL
	CALL	ColourToPalette	;Do the fade routine.
	tst.w	d0	;Has the fade finished yet?
	bne.s	.f_mid	;If not, keep doing it.

	moveq	#2,d1	;d0 = Speed of fade.
	move.l	GS_Palette(a0),a1	;a1 = Source palette.
	moveq	#$000000,d2	;d2 = Destination colour.
.f_out	CALL	Wait_OSVBL
	CALL	PaletteToColour	;Do the fade routine.
	tst.w	d0	;Has the fade finished yet?
	bne.s	.f_out	;If not, keep doing it.

	moveq	#20,d0
	CALL	Wait_Time
	rts

;===========================================================================;
;                                  DATA
;===========================================================================;

GMS_Name:
	dc.b	"games.library",0
	even
GMS_Base:
	dc.l	0

Screen:	dc.l	GSV1,0	;Version header.
	dc.l	0,0,0	;Screen memory pointers 1/2/3
	dc.l	0	;Screen link.
	dc.l	0	;Address of palette.
	dc.l	0	;Address of rasterlist.
	dc.l	0	;Amt of colours in palette.
	dc.w	320,256	;Screen Width and Height.
	dc.w	320/8,256	;Picture Width/8 and Height.
	dc.w	0	;Amt of planes.
	dc.w	0,0	;X/Y screen offsets
	dc.w	0,0	;X/Y picture offsets.
	dc.l	0	;Special attributes.
	dc.w	LORES|COL24BIT	;Screen mode.
	dc.b	INTERLEAVED	;Screen type
	dc.b	0	;Reserved.
	even

Picture	dc.l	PCV1,0	;Version header.
	dc.l	0	;Source data.
	dc.w	320/8,256	;Width in bytes, Height.
	dc.w	0	;Amount of Planes.
	dc.l	0	;Amount of colours.
	dc.l	0	;Source palette (remap).
	dc.w	LORES|COL24BIT	;Screen mode.
	dc.w	INTERLEAVED	;Destination
	dc.l	GETPALETTE|VIDEOMEM	;Options.
	dc.l	.File
.File	dc.b	"GAMESLIB:data/IFF.Loading",0
	even