;Random Plot
;-----------
;This is a graphical demonstration of the Random() functions.  The default
;is to use FastRandom, but you can change it to SlowRandom if you look
;below.
;
;LMB exits.

	opt	o+,c+

	INCLUDE	"exec/exec_lib.i"
	INCLUDE	"games/games_lib.i"
	INCLUDE	"games/games.i"

Random	=	_LVOFastRandom

CALL	MACRO
	jsr	_LVO\1(a6)
	ENDM

	SECTION	"RandomPlot",CODE

;===========================================================================;
;                             INITIALISE DEMO
;===========================================================================;

Start:	MOVEM.L	A0-A6/D1-D7,-(SP)
	move.l	($4).w,a6
	lea	GMS_Name(pc),a1
	moveq	#$00,d0
	CALL	OpenLibrary
	move.l	d0,GMS_Base
	beq.s	.Error_GMS

	move.l	GMS_Base(pc),a6
	sub.l	a0,a0
	CALL	SetUserPrefs

	lea	Screen(pc),a0
	CALL	Add_Screen
	tst.l	d0
	bne.s	.Error_Screen

	CALL	Show_Screen
	CALL	InitJoyPorts
	bsr.s	Main

.ReturnToDOS
	move.l	GMS_Base(pc),a6
	lea	Screen(pc),a0
	CALL	Delete_Screen
.Error_Screen
	move.l	GMS_Base(pc),a1
	move.l	($4).w,a6
	CALL	CloseLibrary
.Error_GMS
	MOVEM.L	(SP)+,A0-A6/D1-D7
	moveq	#$00,d0
	rts

;===========================================================================;
;                                MAIN LOOP
;===========================================================================;

Main:	move.l	GMS_Base(pc),a6
	lea	Screen(pc),a0
.loop	moveq	#JPORT1,d0
	CALL	Read_Mouse
	btst	#MB_LMB,d0
	bne.s	.done

	moveq	#31,d1	;Get random colour.
	jsr	Random(a6)	;>> = Get random number.
	addq.l	#1,d0
	move.l	d0,d3	;d3 = Colour to use.

	move.l	#319+1,d1	;Get random X.
	jsr	Random(a6)	;>> = Get random number.
	move.w	d0,d4	;d4 = Store X to use.

	move.l	#255+1,d1	;Get random Y.
	jsr	Random(a6)	;>> = Get random number.
	move.w	d0,d2	;d2 = Y to use.
	move.w	d4,d1	;d1 = Get back X.

	moveq	#BUFFER1,d0
	CALL	Draw_Pixel

	bra.s	.loop
.done	rts
;===========================================================================;
;                                  DATA
;===========================================================================;

GMS_Name:
	dc.b	"games.library",0
	even
GMS_Base:
	dc.l	0

AMT_PLANES =	5

Screen:	dc.l	GSV1,0	;Structure Version.
	dc.l	0,0,0	;Screen memory 1/2/3
	dc.l	0	;Screen link.
	dc.l	.Palette	;Address of palette.
	dc.l	0	;Address of rasterlist.
	dc.l	0	;Amt of colours in palette.
	dc.w	320,256	;Screen Width, Height.
	dc.w	320/8,256	;Picture Width/8, Height.
	dc.w	AMT_PLANES	;Amt_Planes
	dc.w	0,0	;X/Y screen offsets.
	dc.w	0,0	;X/Y picture offsets.
	dc.l	0	;Special attributes.
	dc.w	LORES|COL12BIT	;Screen mode.
	dc.b	INTERLEAVED	;Screen type
	dc.b	0	;Reserved
	even

.Palette
	dc.w	$000,$190,$FCB,$FA9,$D88,$965,$644,$211
	dc.w	$406,$444,$FF0,$432,$CC0,$190,$501,$880
	dc.w	$261,$271,$382,$492,$5A3,$5B4,$677,$6C4
	dc.w	$788,$9AA,$BCC,$801,$901,$A02,$701,$601