;Install script for Adagis v4.0
;© 1996 Stv
;
;Ask for everything needed
;
(set #directory
	(askdir
		(prompt "Dónde quieres instalar los ficheros de Adagis ?\n(se creará un cajón 'Adagis4')")
		(help @askdir-help)
		(default "Sys:")
	)
)
(set #programdir
	(askdir
		(prompt "Dónde quieres instalar el programa ?\n(no se creará cajón)")
		(help @askdir-help)
		(default "Sys:WBStartup")
	)
)
(set #adddocs
	(askbool
		(prompt "\n\nCopio la documentación del programa ?")
		(help @askbool-help)
	)
)
(set #icon
	(askchoice
		(help @askchoice-help)
		(prompt "Seleccion qué icono quieres instalar para el programa")
		(choices "<Estilo NewIcon 1" "Estilo NewIcon 2" "Estilo NewIcon 3" "Esticlo MWB 1" "Estilo MWB 2" "Estilo IGFX")
		(default 3)
	)
)
(set #icondrawer
	(askchoice
		(help @askchoice-help)
		(prompt "Selecciona qué icono para el cajón quieres instalar")
		(choices "NewIcon-Style1" "MWB-Style 1")
		(default 1)
	)
)
(set #addons
	(askchoice
		(help @askchoice-help)
		(prompt "Qué AddOn quieres usar ?\nVer la documentación para más información")
		(choices "AddOn para Adagis" "AddOn para IntuiCookie")
		(default 0)
	)
)
(set #havedata
	(askbool
		(prompt "\n\nLa distribución de Adagis ha cambiado: no hay fichero de refarnes en este archivo.\n\n"
			"Consigue el fichero 'Adagisv10_dat.lha', el cual contiene una colección de refranes en inglés,"
			"catalán y español. Sin estos ficheros, Adagis no sirve para nada.\n\n"
			"Tienes un fichero de refranes de una versión anterior de Adagis (o de IntuiCookie) ?")		
		(help @askbool-help)
	)
)
(if (= 1 #havedata)
	(set #datafile
		(askfile
			(prompt "Qué fichero de refranes quieres usar ?")
			(help @askfile-help)
			(default "s:adagis.data")
		)
	)
	(message
		"\n\nNo te olvides de configurar Adagis a través de AdagisPrefs una vez tengas tu fichero de refranes instalado"
	)
)
(set #locales
	(askoptions
		(prompt "Qué catálogos quieres instalar ?")
		(help @askoptions-help)
		(choices "Español" "Català")
		(default %01)
	)
)
;
; Now the real installation process starts !
;
(set #fullinstdir (tackon #directory "Adagis4"))				; The install dir
(set @default-dest #fullinstdir)								; Def install dir.
(makedir
	(#fullinstdir)
	(prompt "Crear el directorio de Adagis")
	(help @makedir-help)
	(infos)
)
(copyfiles
	(source "/files/AddOns")
	(dest (tackon #fullinstdir "AddOns"))
	(prompt "Copiar los AddOns")
	(all)
	(infos)
	(help @copyfiles-help)
)
(copyfiles
	(source "/files/rexx")
	(dest (tackon #fullinstdir "Rexx"))
	(prompt "Copiar el directorio de ejemplos ARexx")
	(all)
	(help @copyfiles-help)
)
(copyfiles
	(source "/files/bin/adagisprefs")
	(dest #fullinstdir)
	(prompt "Copiar el programa de preferencias")
	(infos)
	(help @copyfiles-help)
)
(if (= 1 #adddocs)											; Install documentation ?
	(copyfiles
		(source "/docs/adagis4.esp.guide")
		(dest #fullinstdir)
		(prompt "Copiar la documentación")
		(help @copyfiles-help)
		(infos)
	)
)
(copyfiles													; Install Adagis executable.
	(source "/files/bin/Adagis")
	(dest #programdir)
	(prompt "Copiar el ejecutable de Adagis")
	(help @copyfiles-help)
)
(select #icon
	(set #iconfile "/icons/NewIcon_Style1.info")
	(set #iconfile "/icons/NewIcon_Style2.info")
	(set #iconfile "/icons/NewIcon_Style3.info")
	(set #iconfile "/icons/MWB_Style1.info")
	(set #iconfile "/icons/MWB_Style2.info")
	(set #iconfile "/icons/IGFX_Style.info")
)
(copyfiles													; Install Adagis icon.
	(source #iconfile)
	(dest #programdir)
	(newname "Adagis.info")
	(prompt "Copiar el icono")
	(help @copyfiles-help)
)
(select #icondrawer
	(set #iconfile "/icons/NewIcon_Drawer1.info")
	(set #iconfile "/icons/MWB_Drawer1.info")
)
(copyfiles													; Install Adagis drawer icon.
	(source #iconfile)
	(dest #directory)
	(newname "Adagis4.info")
	(prompt "Copiar el icono del cajón")
	(help @copyfiles-help)
)
(tooltype
	(dest (tackon #programdir "Adagis"))
	(settooltype "ADAGISPREFS" (tackon #fullinstdir "AdagisPrefs"))
	(prompt "Modificar el tooltype ADAGISPREFS")
	(help @tooltype-help)
)
(if (= 0 #addons)
	(set #addonfile (tackon #fullinstdir "AddOns/adagis_adagis.addon"))
	(set #addonfile (tackon #fullinstdir "AddOns/adagis_ic.addon"))
)
(run ('/files/bin/cdac "%s" "%s"' #datafile #addonfile )
	(prompt "Crear la configuración por defecto")
	(help @run-help)
)
(if (in #locales 0)
	(copyfiles
		(source "/files/locale/catalogs/español")
		(dest "locale:catalogs/español")
		(prompt "Instalando catálogos")
		(all)
		(help @copyfiles-help)
	)
)
(if (in #locales 1)
	(copyfiles
		(source "/files/locale/catalogs/català")
		(dest "locale:catalogs/català")
		(prompt "Instalando catálogos")
		(all)
		(help @copyfiles-help)
	)
)