1000 DIM Dev$(5),V$(4),Dat$(20)
1010 Dev$="Flp1_":V$=VER$
1020 True%=NOT(0):False%=NOT(True%)
1030 REMark -- PDTK TOOLKIT --
1040 _Base=RESPR(3008):LBYTES Dev$&"PDTK_rext",_Base:CALL _Base
1050 REMark -- TURBO TOOLKIT --
1060 REMark * TURBO keywords must be
1070 REMark   initialised before other
1080 REMark   toolkit keywords with the
1090 REMark   with the same name.
1110 _Base=RESPR(7204):LBYTES Dev$&"TURBO_TOOLKIT_code",_Base:CALL _Base
1120 REMark -- INITIALISE PDTK TOOLKIT --
1130 PDTK_EXT
1140 REMark -- CHECK IF ROM AREA FREE --
1150 SoftROM%=False%
1160 IF PEEK_L(49152)<>HEX("4AFB0001") THEN 
1170  Arbitrary=HEX("ABBA1978")
1180  POKE_L 49152,Arbitrary
1190  IF PEEK_L(49152)=Arbitrary THEN 
1200   POKE_L 49152,0
1210   SoftROM%=True%
1220  END IF 
1230 END IF 
1240 REMark -- TK2 TOOLKIT --
1250 IF WHERE("TK2_EXT")>0 THEN 
1260  TK2_EXT
1270  TOOLKILL
1280 ELSE 
1290  IF SoftROM% AND FTEST(Dev$&"TK2_rom")=0 THEN 
1300   LBYTES Dev$&"TK2_rom",49152
1310   RESET
1320  ELSE 
1330   INSTALL(Dev$&"TK2_cde")
1340   IF WHERE("TK2_ext")>0 THEN 
1350    TK2_EXT
1360    TOOLKILL
1370   END IF 
1380  END IF 
1390 END IF 
1400 REMark -- D68K TOOLKIT --
1410 INSTALL(Dev$&"D68K_rext")
1420 REMark -- DIY RANDOM ACCESS --
1430 INSTALL(Dev$&"RANDOM_code")
1440 REMark -- DIY SEARCH MEM --
1450 INSTALL(Dev$&"SEARCH2_code")
1460 REMark -- QLIB LIBRARIES --
1470 INSTALL(Dev$&"QLIB_runtimes")
1480 REMark -- DIY TOOLKIT --
1490 INSTALL(Dev$&"DIY_code")
1500 REMark -- SPEEDSCREEN --
1510 INSTALL(Dev$&"SPEEDSCREEN_code")
1520 REMark -- INSTALL RAM DISK --
1530 IF DDTEST("RAM") THEN 
1540  INSTALL(Dev$&"DYNAMIC_RAMDRIVE_cde")
1550  IF DDTEST("RAM") THEN 
1560   INSTALL(Dev$&"RAMDISC_cde")
1570   IF DDTEST("RAM")=0 THEN 
1580    FORMAT "ram1_128"
1590   END IF 
1600  END IF 
1610 END IF 
1620 REMark -- DATE AND TIME --
1630 Dat$=DATE$
1640 IF Dat$(1 TO 4)="1961" THEN 
1650  IF FTEST(Dev$&"SETDATE_task")=0 THEN 
1660   EXEC_W Dev$&"SETDATE_task"
1670  END IF 
1680 END IF 
1690 REMark -- SET NICE WINDOW --
1700 MODE 512
1710 REMark SET_DISPLAY 6,25
1720 REMark -- SYSTEM INFO --
1730 Dat$=DATE$
1740 CLS#0:CLS#2:CLS:PRINT\" QDOS version ";QDOS$\" BASIC version ";VER$\\" ";DAY$;" ";Dat$(10 TO 11);Dat$(5 TO 9);Dat$(1 TO 4);\\
1750 IF SoftROM% THEN PRINT " ROM area 49152 to 65536 free":END IF 
1765 PRINT " ";FREE_MEM;" bytes available"\\
1770 STOP
1780 :
1790 DEFine PROCedure SET_DISPLAY(B%,C%)
1800  LOCal N%,M%
1810  IF PEEK(SYSBASE+50)<>0 THEN N%=40:M%=10:ELSE :N%=0:M%=0:END IF 
1820  WINDOW#1;512,256,0,0:PAPER#1;0:CLS#1
1830  WINDOW#0;504-2*N%-6*C%,2+B%*10,N%,254-B%*10:PAPER#0;4:INK#0;0:BORDER#0;1,0:WINDOW#1;8+6*C%,254-M%,504-N%-6*C%,2+M%:PAPER#1;1:INK#1;7:BORDER#1;2,7:WINDOW#2;504-2*N%-6*C%,252-M%-B%*10,N%,2+M%:PAPER#2;2:INK#2;7:BORDER#2;1,0
1840  CLS#0:CLS#1:CLS#2
1850 END DEFine 
1860 REMark ---- INSTALL A TOOLKIT ----
1870 DEFine PROCedure INSTALL(file$)
1880  LOCal size
1890  IF FTEST(file$)=0 THEN 
1900   LRESPR(file$)
1910   TOOLKILL
1920  END IF 
1930 END DEFine INSTALL
