;YAM Installation script
;by Marcel Beck

(complete 0)

(if (= @language "english")
   (
   (set locale 0)
   (set #bad-MUI     (cat "You need at least MUI3.1 to use YAM."))
   (set #no-AmiTCP   (cat "\"AmiTCP:\" assign not found.\nYAM needs at least AmiTCP 2.3 to run.\nMake shure AmiTCP is installed properly."))
   (set #dir-choice  (cat "Select the directory where YAM has to be installed." ))
   (set #copy        (cat "Copying YAM"))
   (set #doc-choice  (cat "Where do you want to install the documentation?\nIf you want the HELP key to work you should use the given path."))
   (set #doc-copy    (cat "Copying Documentation"))
   (set #cat-copy    (cat "Copying Catalog"))
   (set #modify_ss   (cat "Adding YAM assign to your \"s:user-startup\" file."))
   ))

(if (= @language "deutsch")
   (
   (set locale 2)
   (set #bad-MUI     (cat "Sie benötigen mindestens MUI3.1, um YAM zu nutzen."))
   (set #no-AmiTCP   (cat "\"AmiTCP:\" Zuweisung nicht gefunden.\nYAM benötigt mindestens AmiTCP 2.3.\nStellen Sie sicher, dass AmiTCP ordnungsgemäss installiert ist"))
   (set #dir-choice  (cat "Wählen Sie das Verzeichnis aus, in welches YAM installiert werden soll."))
   (set #copy        (cat "Kopiere YAM"))
   (set #doc-choice  (cat "Wohin möchten Sie die Dokumentation kopieren ?\nWenn Sie möchten, dass die HELP-Taste funktioniert, sollten Sie das vorgeschlagene Verzeichnis benutzen."))
   (set #doc-copy    (cat "Kopiere Dokumentation"))
   (set #cat-copy    (cat "Kopiere Katalog"))
   (set #modify_ss   (cat "Erstelle YAM Zuweisung in Ihrer \"s:user-startup\"-Datei."))
   ))

(set versionnumber (getversion "MUI:MUI"))
(set version (/ versionnumber 65536))
(if (< version 11 )
   ((message #bad-MUI) (if (= @user-level 0) (abort "Couldn't find MUI >=V11"))))

(set yam-dir "AmiTCP:")
(if (NOT(exists "AmiTCP:" (noreq)))
   ((message #no-AmiTCP) (if (= @user-level 0) (abort "Couldn't find AmiTCP:"))))

(set yam-dir (askdir (prompt #dir-choice) (default yam-dir) (help @askdir-help)))
(set @default-dest (tackon yam-dir "YAM"))
(makedir @default-dest (infos))

(complete 20)
(copyfiles (prompt #copy) (source "/YAM") (newname "YAM") (help @copyfiles-help) (infos) (dest @default-dest))
(copyfiles (source "/Icons") (all) (dest (cat @default-dest "/Icons")))
(copyfiles (source "/Rexx") (all) (dest (cat @default-dest "/Rexx")))

(complete 40)
(set doc-dir @default-dest)
(set doc-dir (askdir (default @default-dest) (prompt #doc-choice) (help @askdir-help)))
(copyfiles (prompt #doc-copy) (source (cat "/Docs/YAM_" @language ".guide")) (newname "YAM.guide")
   (help @copyfiles-help) (infos) (optional force) (dest doc-dir))

(complete 60)
(if locale (
   (copyfiles (prompt #cat-copy) (source (cat "/Catalogs/" @language "/YAM.catalog"))
      (newname "YAM.catalog") (help @copyfiles-help) (optional force)
      (dest (cat "LOCALE:Catalogs/" @language))))
)

(complete 80)
(makeassign "YAM" @default-dest)
(startup "YAM" (prompt #modify_ss) (help @startup-help) (command "Assign YAM: \"" @default-dest "\"\n"))

(complete 100)