/** $VER: RemiseCheque1 1.1 (01.05.98)
 ** Auteur: Fabrice SABATIER
 **
 ** Commande ARexx sous GestaLivre V2.0.
 **
 ** Utilisation de Wordworth7® pour imprimer les remise de chèques.
 **
 **/

OPTIONS RESULTS

Tab            = '09'x      /* caractère de tabulation */
NL             = '0a'x      /* caractère Retour chariot */

/*****************  Définit les variables d'environnement   ***********************/

ADDRESS COMMAND "SYS:Rexxc/rx ENV:GestaCompte.ARexxPréfs" /* exécute le script de définitions des préférences */
NOM_PORT_LIVRE   =GETCLIP('Port_Livre')
NOM_ECRAN_PUB    =GETCLIP('Ecran_Livre')
NOM_PORT_FINAL   =GETCLIP('Port_TraitementTexte')
REPERTOIRE       =GETCLIP('Chemin')

/************************************************************************/

SIGNAL ON SYNTAX            /* détourne les messages d'erreurs */

IF~SHOW(L,"rexxsupport.library")THEN DO
 IF~ADDLIB("rexxsupport.library",0,-30,0) THEN DO
     SAY "rexxsupport.library est introuvable !"
     EXIT
 END
END

/* ouvre la library rexxreqtools.library pour les messages d'erreurs */
call addlib("rexxreqtools.library",0,-30,0)

WW=1
IF~SHOW(p,NOM_PORT_FINAL) THEN DO
  WW=0
  ADDRESS COMMAND "WBStarter "||REPERTOIRE||" >NIL:"
  DO 10
     IF SHOW(p,NOM_PORT_FINAL) THEN DO
         WW=1
         LEAVE
         END
     CALL DELAY(100)
  END
END

IF WW THEN DO


ADDRESS VALUE NOM_PORT_LIVRE /* adresse du port Arexx du livre de caisse */
wait 5
exportdata ASCII "ram:export"
ADDRESS VALUE NOM_PORT_FINAL /* Adresse du port ARexx de Wordworth7® */
Open Filename "GESTA:FeuillesdeStyle/RemisedeCheque.ww"    /* ouvre le fichier RemisedeCheque */

SommeTotal=0

x=OPEN('infos','ram:export','R') /* ouvre le fichier exporté */
DO i=1 BY 1 WHILE ~EOF('infos')  /* lit ce fichier jusqu'à la fin */
ligne.i=READLN('infos')          /* et le place dans le tableau indicé i */
END

ligne.0=i-1            /* place le nombre de lignes du tableau en 0 */
x=CLOSE('infos')       /* ferme le fichier */

IF ligne.0>40 THEN ligne.0=40


 GotoLine 1 
 Font SIZE "12" BOLD
 Text Tab
 InsertDate                /* mise à jour de la date */


 GotoLine 8              /* positionne le curseur dans le tableau */
 Font SIZE "8" PLAIN 

DO i=1 TO ligne.0-1         /* passe toutes les lignes du tableau en revue */
 PARSE VAR ligne.i jour '/' mois '/' nature '/' somme '/' libelle '/' compte '/' NumCheque '/' Banque '/' Nom '/' .

 IF LEFT(nature,5)="Bank1" THEN DO    /* envoi à Wordworth7 les transactions de Banque1 */

 IF Banque= "CL" THEN Banque= "Crédit Lyonnais"
 IF Banque= "SG" THEN Banque= "Société Générale"
 IF Banque= "SMC" THEN Banque= "Société Marseillaise de Crédit"
 IF Banque= "CA" THEN Banque= "Crédit Agricole"
 IF Banque= "CFF" THEN Banque= "Crédit Foncier de France"
 IF Banque= "CM" THEN Banque= "Crédit Mutuel"
 IF Banque= "CCP" THEN Banque= "Compte Chèque Postal"

 Text Tab /* envoie le caractère de tabulation 09 en ASCII */
 Text nom /* saisie de la ligne */
 Text Tab
 Text NumCheque
 Text Tab
 Text Banque
 Text Tab
 Text somme
 SommeTotal=SommeTotal+somme
 END
 Line 1
END


 GotoLine 72            /* positionne le curseur en fin de page */

 Font SIZE "12" BOLD
 Text Tab
 Text SommeTotal

 Saveas Name "GESTA:Bordereaux/BordBanque1Du_" || jour || mois  
/*Print*/
/*Quit*/

ADDRESS COMMAND 'delete ram:export' /* libère la mémoire */

END
EXIT

/* Traite les messages d'erreurs */
SYNTAX:
IF RC=13 THEN call rtezrequest( "      Environnement serveur non trouvé !!!" || NL || NL ||,
                                "Le nom du port ARexx utilisé dans le script est : "|| NL || NL ||,
                                "-----------------------------------------------"|| NL ||,
                                "                  " || NOM_PORT_LIVRE || NL ||,
                                "-----------------------------------------------"|| NL || NL ||,
                                "Note : Pour réparer ceci, veuillez fermer le module"|| NL ||,
				"       'Livre' et modifier le type d'outil 'REXX' de"|| NL ||,
				"       l'icône, puis le relancer."|| NL || NL ||,
				"       ATTENTION aux minuscules/majuscules      ",,
				"OK", "Informations","rt_pubscrname="||NOM_ECRAN_PUB "rt_font=Gestacompte.font/8")
ELSE call rtezrequest(errortext(RC),"Vu",,"rt_pubscrname="||NOM_PORT_LIVRE "rt_font=Gestacompte.font/8")

ADDRESS VALUE NOM_PORT_FINAL
QUIT (force)

EXIT