(welcome)

(set #destdir
	(askdir
		(prompt "Where should the Iris drawer be created?")
		(default @default-dest)
		(help @askdir-help)
	)
)
(set @default-dest #destdir)
(set #parent-dir #destdir)
(set #doc-dir
	(askdir
		(prompt "Where do you want to install the documentation (AmigaGuide)?")
		(default (tackon #destdir "Iris"))
		(newpath)
		(help @askdir-help)
	)
)
(set #icons
	(askchoice
		(prompt "Which icons do you want to install?")
		(choices "Standard" "MagicWB")
		(default 0)
		(help @askchoice-help)
	)
)

(set #browsewww
	(askfile
		(prompt "Which WWW browser do you use?")
		(help @askfile-help)
		(default "BrowseWWWscripts/AWeb")
	)
)
(if (not (patmatch "#?AWeb#?" #browsewww))
	(message "Warning: the selected script has not been tested.")
)

(set #ext
	(askchoice
		(prompt "Which version of the bgui.library do you want to install?")
		(choices "Standard" "Extended (AmigaOS 3.0 and 68020 required)")
		(default 0)
		(help @askchoice-help)
	)
)
(if (= #ext 0)
	(set #bgui-lib "libs/bgui.library")
	(set #bgui-lib "libs/bgui.library_e")
)
(set #lib-dest
	(askdir
		(prompt "Where should the bgui.library be installed?\nA version check will be performed.")
		(help @askdir-help)
		(default "LIBS:")
	)
)
(set #classes-dest
	(askdir
		(prompt "Where should the class 'bgui_popbutton.gadget be installed?")
		(help @askdir-help)
		(default "LIBS:Gadgets/")
		(newpath)
	)
)

(copylib
	(prompt "Copying bgui.library...")
	(confirm)
	(source #bgui-lib)
	(dest #lib-dest)
	(newname "bgui.library")
	(help @copylib-help)
)
(copylib
	(prompt "Copying bgui_popbutton.gadget")
	(confirm)
	(source "classes/gadgets/bgui_popbutton.gadget")
	(dest #classes-dest)
	(help @copylib-help)
)

(set #destdir (tackon #destdir "Iris"))
(set @default-dest #destdir)
(makedir #destdir)
(set #buttons-dest (tackon #destdir "Buttons"))
(makedir #buttons-dest)
(makedir (tackon #destdir "Mail"))
(copyfiles
	(prompt "Copying program...")
	(source "Iris")
	(dest #destdir)
	(infos)
	(noposition)
)
(copyfiles
	(prompt "Copying buttons...")
	(source "Buttons/")
	(dest #buttons-dest)
	(infos)
	(all)
)
(copyfiles
	(prompt "Copying BrowseWWW.rexx script...")
	(source #browsewww)
	(dest #destdir)
	(newname "BrowseWWW.rexx")
	(infos)
	(noposition)
)
(copyfiles
	(prompt "Copying Poll.irx script...")
	(source "Poll.irx")
	(dest #destdir)
	(infos)
	(noposition)
)
(copyfiles
	(prompt "Copying documentation...")
	(source "Iris.guide")
	(dest #doc-dir)
	(infos)
	(all)
)

(if (= #icons 1)
	(
		(copyfiles
			(prompt "Copying MagicWB style drawer icon...")
			(source "MWB-Icons/Iris_drw.info")
			(dest #parent-dir)
			(newname "Iris.info")
			(infos)
			(noposition)
		)
		(copyfiles
			(prompt "Copying MagicWB style program icon...")
			(source "MWB-Icons/Iris.info")
			(dest #destdir)
			(infos)
			(noposition)
		)
		(copyfiles
			(prompt "Copying MagicWB style Buttons drawer icon...")
			(source "MWB-Icons/Buttons.info")
			(dest #destdir)
			(infos)
			(noposition)
		)
		(copyfiles
			(prompt "Copying MagicWB style guide icon...")
			(source "MWB-Icons/Iris.guide.info")
			(dest #doc-dir)
			(infos)
			(noposition)
		)
		(copyfiles
			(prompt "Copying MagicWB style Poll.irx icon...")
			(source "MWB-Icons/Poll.irx.info")
			(dest #destdir)
			(infos)
			(noposition)
		)
	)
	(copyfiles
		(prompt "Copying drawer icon...")
		(source "/Iris.info")
		(dest #parent-dir)
		(infos)
		(noposition)
	)
)