incdir  include:
                incdir  lvo:

**      '(C) Copyright 1997 Haage & Partner Computer GmbH'
**           All Rights Reserved

                include powerpc/ppcmacros.i
                include powerpc/powerpc.i
                include powerpc/tasksppc.i

                include powerpc_lib.i
                include exec_lib.i
                include dos_lib.i

                xref    _SysBase
                xref    _DOSBase
                xref    _PowerPCBase
                xref    _LinkerDB
                smalldata
                executable
                escapestr
                version 10

start
                prolog  1024
                push    r31
                la      _d1,template
                la      _d2,Array
                li      _d3,0
                RUN68K_XL       _DOSBase,ReadArgs
                tstw    _d0
                beq     .close
                mr      r31,_d0
                lw      r3,Array
                tstw    r3
                beq     .show
                lwz     r4,0(r3)
                CALLPOWERPC     ChangeStack
                b       .done
.show
                li      r4,0
                CALLPOWERPC     FindTaskPPC
                lwz     r3,TASKPPC_STACKSIZE(r3)
                sw      r3,Args
                la      _d1,showsize
                la      _d2,Args
                RUN68K_XL       _DOSBase,VPrintf
.done
                mr      _d1,r31
                RUN68K_XL       _DOSBase,FreeArgs
.close
                pop     r31
                epilog

                section data
template        dc.b    "SIZE/N",0
showsize        dc.b    "The current PPC stack size is: %ld bytes\n",0

                section bss
                ds.b    32
Array           ds.l    1
Args            ds.l    1
                ds.b    32
                even