incdir  include:
                incdir  lvo:

**      '(C) Copyright 1997 Haage & Partner Computer GmbH'
**           All Rights Reserved

                include powerpc/ppcmacros.i
                include powerpc/powerpc.i
                include powerpc/tasksppc.i

                include powerpc_lib.i
                include exec_lib.i
                include dos_lib.i

                xref    _SysBase
                xref    _DOSBase
                xref    _PowerPCBase
                xref    _LinkerDB
                smalldata
                executable
                escapestr
                version 10

start
                prolog  1024
                push    r31
                la      _d1,template
                la      _d2,Array
                li      _d3,0
                RUN68K_XL       _DOSBase,ReadArgs
                tstw    _d0
                beq     .close
                mr      r31,_d0
                la      r3,Array
                lwz     r4,0(r3)
                tstw    r4
                bne     .standard
                lwz     r4,4(r3)
                tstw    r4
                bne     .bat
                li      r4,0
                CALLPOWERPC     FindTaskPPC
                lwz     r3,TASKPPC_FLAGS(r3)
                bittst  r3,TASKPPCP_BAT
                bne     .showBAT
                la      _d1,showpaged
                b       .printinfo
.showBAT
                la      _d1,showBAT
.printinfo
                la      _d2,Args
                RUN68K_XL       _DOSBase,VPrintf
                b       .done
.bat
                li      r4,CHMMU_BAT
                CALLPOWERPC     ChangeMMU
                b       .done
.standard
                li      r4,CHMMU_STANDARD
                CALLPOWERPC     ChangeMMU
.done
                mr      _d1,r31
                RUN68K_XL       _DOSBase,FreeArgs
.close
                pop     r31
                epilog

                section data
template        dc.b    "S=STANDARD/S,B=BAT/S",0
showpaged       dc.b    "This task runs under standard paged MMU setup\n",0
showBAT         dc.b    "This task runs under BAT MMU setup\n",0

                section bss
                ds.b    32
Array           ds.l    2
Args            ds.l    1
                ds.b    32
                even