;
; Installer-script for the installation of MuMu
;
;	$VER: Install MuMu 1.0 (06.01.94) by Litrik De Roy
;

(set @default-dest "")

(set #not_root "\n\nYou must be logged in\nas 'root' to install MuMu !")
(set #bad_kick "You must be using Kickstart 2.04 (or higher) !")

(set #install-msg
	(cat "\nMuMu installation script.\n\n"
   	  "This script installs MuMu 1.0 on your Amiga.\n\n"
	     "Read the documentation for\n"
   	  "information on the usage of MuMu.\n"
   	  "\nMuMu © 1994 Litrik De Roy\n"
	     "All rights reserved."
	)
)

(set #utility-msg
	(cat "    These utilities are used in the scripts "
   	  "and are probably useful even if you're "
	     "going to edit the scripts.\n\n"
	)
)

;=============================================================================
; make sure we are running under a 2.04 ROM

(if (< (/ (getversion) 65536) 37)
(
    (abort #bad_kick)
))

;=============================================================================
; make sure we are root

(run "setenv install_user `UserInfo QUICK`")
(if (NOT (= (getenv "install_user") "root"))
	(
		(abort #not_root)
	)
)

(welcome)

;=============================================================================
; say hi

(message #install-msg)

;=============================================================================
; 

(run "setenv install_home $home")
(set home ("%s" (getenv "install_home")))

(copyfiles
	(prompt "Copying executable...")
	(help @copyfiles-help)
	(source "MuMu")
	(dest "SYS:WBstartup")
	(infos)
	(confirm)
)

(run "MProtect SYS:WBstartup/MuMu GROUP RWED OTHER RWED SUB")
(run "MProtect SYS:WBstartup/MuMu.info GROUP RWED OTHER RWED SUB")

(complete 30)


(copyfiles
	(prompt "Copying scripts...")
	(help @copyfiles-help)
	(source "S")
	(dest (cat home "/S"))
	(all)
	(confirm)
)

(complete 55)

(copyfiles
	(prompt "Copying utilities...")
	(help (cat #utility-msg @copyfiles-help))
	(source "C")
	(dest "C:")
	(all)
	(confirm)
)

(complete 75)

(copyfiles
	(prompt "Copying doc...")
	(help @copyfiles-help)
	(source "")
	(dest (cat home "/docs"))
	(pattern "MuMu.guide#?")
	(confirm)
)

(complete 100)