;----------------------------
; Check version and install if newer
; IN:	#source-file
;	#dest-file

(procedure P_install
  (if
    (exists #dest-file)
    (
      (set #sver (getversion #source-file))
      (set #dver (getversion #dest-file))
      (if
        (>= #sver #dver)
        (
          (if
            (= @user-level 2)
            (set #choice
              (askbool
                (prompt ("\nInstalling\n\n\"%s\" Version %ld.%ld\n\nover\n\n\"%s\" Version %ld.%ld" (fileonly #source-file) (/ #sver 65536) (BITAND #sver 65535) #dest-file (/ #dver 65536) (BITAND #dver 65535)))
                (default 1)
                (choices "Install" "Skip")
                (help @askbool-help)
              )
            )
            (set #choice 1)
          )
        )
        (set #choice 0)
      )
    )
    (set #choice 1)
  )
  (if
    (= #choice 1)
    (copyfiles
      (help @copyfiles-help)
      (source #source-file)
      (dest (pathonly #dest-file))
      (newname (fileonly #dest-file))
    )
  )
)

;----------------------------

(set @default-dest
  (askdir
    (prompt ("Where should %s and the other tools installed ?\nThe location must be reachable via the path !\nRecommend is \"C:\"." @app-name))
    (help @askdir-help)
    (default "C:")
    (disk)
  )
)

(set #path "c")
(foreach #path "#?"
  (set #file @each-name)
  (set #source-file (tackon #path #file))
  (set #dest-file   (tackon @default-dest #file))
  (P_install)
)

(if
  (exists "c/InstallBB")
  (
    (set #dest
      (askdir
        (prompt "Where should \"whdload.i\" installed ?")
        (help @askdir-help)
        (default "Includes:")
      )
    )
    (copyfiles
      (help @copyfiles-help)
      (source "include/whdload.i")
      (dest #dest)
    )
    (set #dest
      (askdir
        (prompt "Where should \"whdload.doc\" installed ?")
        (help @askdir-help)
        (default "Autodocs:")
      )
    )
    (copyfiles
      (help @copyfiles-help)
      (source "autodoc/whdload.doc")
      (dest #dest)
    )
    (exit
      "\n"
      "Installation is so far complete.\n"
      "Now you should move this installation drawer to a persistent place. And examine it. "
      "Take a look at the \"src\" directory and don't forget to read the "
      "Guide the autodoc ...\n"
      "\n"
      "Hope it will be useful for you.\n"
      (quiet)
    )
  )
  (
    (set #dest
      (askdir
        (prompt "Where should \"WHDLoad.guide\" installed ?")
        (help @askdir-help)
        (default "Help:")
      )
    )
    (copyfiles
      (help @copyfiles-help)
      (source "Docs/WHDLoad.guide")
      (dest #dest)
    )
    (set #dest
      (askdir
        (prompt "Where should \"Patcher.Readme\" installed ?")
        (help @askdir-help)
        (default #dest)
      )
    )
    (copyfiles
      (help @copyfiles-help)
      (source "Docs/Patcher.Readme")
      (dest #dest)
    )
    (exit
      "\n"
      "Installation is now complete.\n"
      "Please read the documentation carefully how to use and configure WHDLoad for your needs.\n"
      (quiet)
    )
  )
)