;RawStartup INSTALLATION SCRIPT
;COPYRIGHT ©1996 MICHAEL NEUWEILER

(complete 0)

(set binary-dir
	(askdir
		(prompt "Please select the folder where "
			"the program will be installed")
		(default "C:")
		(help "The C: folder is the default. If you would like "
			"to install it into another folder you will have to "
			"change your Startup-Sequence accordingly.")
	)
)
(set @default-dest binary-dir)

(complete 10)

(copyfiles
	(prompt "Copying the RawStartup binary")
	(source "c/RawStartup")
	(newname "RawStartup")
	(help @copyfiles-help)
	(optional force)
	(dest binary-dir)
)

(complete 30)

(makedir "S:RS"
	(prompt "Installer will create a directory called "
		"S:RS/ where the different startup scripts go in.\n"
		"(RawStartup will check only this directory so it's "
		"strongly suggested you allow Installer to create it.)")
	(help "If you do not want Installer make the changes, you "
		"will have to do them manually.")
	(confirm)
)

(complete 40)

(copyfiles
	(prompt "Creating a default startup script out of "
		"your original Startup-Sequence")
	(help "This will copy S:Startup-Sequence to "
		"S:RS/Default")
	(source "S:Startup-Sequence")
	(dest "S:RS")
	(newname "Default")
	(confirm)
)

(complete 50)

(rename "S:Startup-Sequence" "S:Startup-Sequence.orig"
	(prompt "Renaming S:Startup-Sequence to S:Startup-Sequence.orig "
		"so it won't be overwritten by the installation of the "
		"new Startup-Sequence.")
	(help "If Installer isn't allowed to rename it then it "
		"will be overwritten during the next step.\n"
		"This is just to make it easier for you to restore "
		"your original environment/startup")
	(confirm)
)

(complete 60)

(copyfiles
	(prompt "Copying the new Startup-Sequence which "
		"will start RawStartup immediately after a reboot.")
	(source "S/Startup-Sequence")
	(dest "S:")
	(newname "Startup-Sequence")
	(help @copyfiles-help)
	(optional force)
	(confirm)
)

(complete 70)

(copyfiles
	(prompt "Would you like to install an example script ?\n"
		"(please have a look at the help text !)"
	)
	(help "If you use these example scripts you can press the "
		"following keys during startup:\n\n"
		"F1: Use your old Startup-Sequence (s:RS/Default)\n"
		"F2: Use the original Amiga Startup-Sequence (s:RS/Startup_1.3)\n"
		"F3: Start ShapeShifter with as much memory as possible. (s:RS/Startup_1.4)\n"
		"F4: Start NetBSD (s:RS/Startup_1.5)\n"
		"F5: Original Amiga Startup-Sequence but does not load the CyberGfx driver (Startup_1.6)\n\n"
		"Please have a look at the different scripts in s:RS/ after they have been installed. It's very likely that you have to modify them to get them work with your configuration."
	)
	(source "s/RS")
	(all)
	(dest "S:RS")
	(confirm)
)

;========================================================================
;
; Install the documentation
;

(complete 80)
(set doc-dir "Work:")
(set doc-dir
	(askdir
		(default doc-dir)
		(prompt "Where would you like to install the documentation ?")
		(help "This will copy the Documentation to the selected folder")
	)
)

(copyfiles
	(prompt "Copying the Documentation")
	(source "RawStartup.guide")
	(help @copyfiles-help)
	(optional force)
	(dest doc-dir)
	(infos)
)

(complete 100)