;============================================================================;
;                    PSCalc Installscript by N. DARNIS                       ;
;                  $VER: PSCalc-Install 4.3 (20.3.1997)                      ;
;============================================================================;

(set #pscalc-default-dest "SYS:Tools/Commodities")

(set #pscalc-src "/PSCalc")
(set #doc-icon4-src "/icones/PSCalc.guide4.info")
(set #doc-icon8-src "/icones/PSCalc.guide8.info")

(set #key-src "/PSCalc.key_file")
(set #key-src-icon "/PSCalc.key_file.info")
(set #key-dest "s:")

(if (= @language "français")

;================================ FRANCAIS ==================================;

(
(set #doc-default-dest "HELP:français")

(set #pscalc-icon4-src "/icones/PSCalc_f4.info")
(set #pscalc-icon8-src "/icones/PSCalc_f8.info")

(set #doc-src "/help/français/PSCalc.guide")
(set #catalog-src "/catalogs/français/pscalc.catalog")
(set #images-src "/help/français/")

(set #welcome
	(cat
		"\nBienvenue à l'installation de PSCalc V1.43.\n\n"
		"Ecrit par N. DARNIS,\ndistribué par QUARTZ Informatique.\n"
	)
)

(set #pscalc-dir "Dans quel répertoire voulez-vous installer PSCalc?")
(set #pscalc-dir-help
	(cat
		"Il s'agit du répertoire de destination de PSCalc.\n"
    "Normalement PSCalc devrait être dans SYS:WBStartup ou dans SYS:Tools/Commodities"
	)
)

(set #doc-dir "Dans quel répertoire voulez-vous copier la documentation?")
(set #doc-dir-help
  (cat
    "Il s'agit du répertoire de destination de la documentation.\n"
    "Normalement la documentation doit se trouver dans HELP:français\n"
    "Assurez-vous d'avoir AmigaGuide® ou MultiView® pour lire la documentation"
  )
)

(set #icon-select "Choisissez le type d'icone que vous désirez:")
(set #icon-select-help
	(cat
    "Vous pouvez choisir les icones Magic Workbench (8 couleurs)\n"
    "ou les icones standards en 4 couleurs."
	)
)

(set #icons-normal "Normal (4 couleurs)")
(set #icons-mwb "Magic Workbench (8 couleurs)")

(set #bad-kick "Vous devez posséder le Kickstart 3.0 ou supérieur pour installer PSCalc")
(set #install-exit "Merci d'utiliser PSCalc...")
)

;================================= ENGLISH ==================================;

(
(set #doc-default-dest "HELP:english")

(set #pscalc-icon4-src "/icones/PSCalc_e4.info")
(set #pscalc-icon8-src "/icones/PSCalc_e8.info")

(set #doc-src "/help/english/PSCalc.guide")
(set #images-src "/help/english/")

(set #welcome
	(cat
		"\nWelcome to the install utility of PSCalc V1.43.\n\n"
		"Written by N. DARNIS, distributed by QUARTZ Informatique.\n"
	)
)

(set #pscalc-dir "In which drawer do you want to install PSCalc?")
(set #pscalc-dir-help
	(cat
		"It's the destination drawer of PSCalc.\n"
    "Usually, PSCalc should goes to SYS:WBStartup or to SYS:Tools/Commodities"
	)
)

(set #doc-dir "In which drawer do you want to install the documentation?")
(set #doc-dir-help
  (cat
    "It's the destination drawer of the documentation.\n"
    "Usually, the documentation must go to HELP:english\n"
    "Be sure to have AmigaGuide® or MultiView® to view the documentation"
  )
)

(set #icon-select "Choose the icons you wish to install:")
(set #icon-select-help
	(cat
    "You can choose between Magic Workbench icons (8 colors)\n"
    "and normal icons (4 colors)."
	)
)

(set #icons-normal "Normal (4 colors)")
(set #icons-mwb "Magic Workbench (8 colors)")

(set #bad-kick "You need at least Kickstart 3.0 to install PSCalc")
(set #install-exit "Thank you for using PSCalc...")
)
) ; if language = french

;============================== PROGRAM-START ===============================

(welcome #welcome)

(complete 0)

(set #pscalc-dir-name
  (askdir
    (prompt #pscalc-dir)
    (help #pscalc-dir-help)
    (default #pscalc-default-dest)
  )
)

(complete 10)

(set #doc-dir-name
  (askdir
    (prompt #doc-dir)
    (help #doc-dir-help)
    (default #doc-default-dest)
  )
)

(complete 20)

(copyfiles
  (source #pscalc-src)
  (dest #pscalc-dir-name)
)

(complete 30)

(copyfiles
  (source #doc-src)
  (dest #doc-dir-name)
)

(complete 40)

(set #icon-type
  (askchoice
    (prompt #icon-select)
    (help #icon-select-help)
    (choices #icons-normal #icons-mwb)
    (default 1)
  )
)

(complete 50)

(if (= #icon-type 0)
  (
    (copyfiles
      (source #pscalc-icon4-src)
      (dest #pscalc-dir-name)
      (newname "PSCalc.info")
    )
    (copyfiles
      (source #doc-icon4-src)
      (dest #doc-dir-name)
      (newname "PSCalc.guide.info")
    )
  )
  (
    (copyfiles
      (source #pscalc-icon8-src)
      (dest #pscalc-dir-name)
      (newname "PSCalc.info")
    )
    (copyfiles
      (source #doc-icon8-src)
      (dest #doc-dir-name)
      (newname "PSCalc.guide.info")
    )
    (copyfiles
      (source #images-src)
      (dest #doc-dir-name)
      (pattern "Fen#?")
    )
  )
)

(complete 70)

(copyfiles
  (source #key-src)
  (dest #key-dest)
)

(copyfiles
  (source #key-src-icon)
  (dest #key-dest)
)

(complete 80)

(if (= @language "français")
  (copyfiles
    (source #catalog-src)
    (dest "LOCALE:catalogs/français")
  )
)

(complete 90)

(message #install-exit)

(complete 100)